用于将 getter 函数包装在标识符周围的球拍宏

Question

我想在标识符周围包装一个 getter 和 setter 函数，以便

(define x 1)
(set! x v) ; should expand to (custom-set! x v)
x          ; should expand to (custom-get x)

其中 custom-put! 和 custom-get 在其他地方定义，并添加其他行为，例如日志记录。

在racket guide（第 16.1.6 节）中，有一个 Set!-Transformer 示例，它适用于具有零参数的 setter 和 getter。但是，我需要一个宏，它将标识符出现扩展为以匹配标识符作为其参数的 getter 函数。

我尝试在链接部分采用宏如下：

(define-syntax-rule (generate-accessors id get put!)
(define-syntax id
  (make-set!-transformer
   (lambda (stx)
       (syntax-case stx (set! get)
         [id (identifier? (syntax id)) (syntax (get id))]
         [(set! id e) (syntax (put! id e))])))))

问题是 (syntax (get id)) 导致无限扩展。 有没有一种直接的方法来切断模板表达式的递归？我还考虑过生成一个绑定到 id 的新标识符并将其包含在文字列表中，但我不知道如何实现。

Answer 1

您链接到的示例与上一节中的代码一起使用 定义了get-val 和put-val!：

(define-values (get-val put-val!)
  (let ([private-val 0])
    (values (lambda () private-val)
            (lambda (v) (set! private-val v)))))

(define-syntax val
  (make-set!-transformer
   (lambda (stx)
     (syntax-case stx (set!)
       [val (identifier? (syntax val)) (syntax (get-val))]
       [(set! val e) (syntax (put-val! e))]))))

val ;; 0
(set! val 42)
val ;; 42

---

让我们编写宏编写宏，generate-accessors， 参数化标识符和访问器，看看它是否有效：

(define-syntax (generate-accessors stx)
  (syntax-case stx ()
    [(_ val get-val put-val!)
     (syntax
      (define-syntax val
        (make-set!-transformer
         (lambda (stx)
           (syntax-case stx (set!)
             [val (identifier? (syntax val)) (syntax (get-val))]
             [(set! val e) (syntax (put-val! e))])))))]))

(generate-accessors foo get-val put-val!)
foo ;; 0
(set! foo 42)
foo ;; 42

另外，让我们用另一对访问器来练习它，它显示了一个 像“记录”这样的副作用：

(define-values (custom-get custom-set!)
  (let ([private-val 0])
    (values (lambda () (println "get") private-val)
            (lambda (v) (println "set") (set! private-val v)))))

(generate-accessors bar custom-get custom-set!)
bar ;; 0
(set! bar 42)
bar ;; 42

---

编辑：针对您的评论，这里有一个变体，它为每次调用生成一对新的访问器（和值）。它允许您提供一对要调用的运行时函数来做额外的工作（这里只是println）。 （如果你发现它总是一样的，你可以将它简化为硬编码 println 或 log-debug 或其他东西。）

(require (for-syntax racket/base
                     racket/syntax
                     syntax/parse))

(define-syntax (define/logged stx)
  (syntax-parse stx
    [(_ id:id init:expr on-get:expr on-set:expr)
     #:with get (format-id stx "get-~a" #'id)
     #:with set (format-id stx "set!-~a" #'id)
     #'(begin
         (define-values (get set)
           (let ([v init])
             (values (λ () (on-get 'id v) v)
                     (λ (e) (on-set 'id e) (set! v e)))))
         (define-syntax id
           (make-set!-transformer
            (λ (stx)
              (syntax-parse stx
                [id:id #'(get)]
                [(set! id e) #'(set e)])))))]))

(define (on-get id v)
  (println `(get ,id ,v)))

(define (on-set! id v)
  (println `(set! ,id ,v)))

(define/logged foo 0 on-get on-set!)
foo
(set! foo 42)
foo

;; prints:
;; '(get foo 0)
;; 0
;; '(set! foo 42)
;; '(get foo 42)
;; 42

我不是 100% 清楚您要做什么。也许这更接近，或者至少给你一些想法。

注意这里我切换到syntax-parse，而不是尝试遵循指南中的原始示例。只是因为。