在没有额外括号的宏内映射？

Question

假设我有一个这样的宏：

(define-syntax (choose stx)
  (define data (syntax->datum stx))
  (define args (cadr data))
  (define body (cddr data))
  (define output
    `(apply (case (car ,args)
              ,(map (lambda (choice)
                           `((,(car choice)) ,(cadr choice)))
                         body)
              (else (displayln "error")))
            (cdr ,args)))
  (println output)
  #'(void))

如果我在这样的事情上使用它（可能有更多选择）：

(choose args
        ("run" runsomething)
        ("del" delsomethingelse))

将其转换为

(apply
 (case (car args)
   ((("run") runsomething)
    (("del") delsomethingelse))
   (else (displayln "error")))
 (cdr args))

这不是有效的代码，因为地图给了它额外的括号。相反，我希望它给我这个：

(apply
 (case (car args)
   (("run") runsomething)
   (("del") delsomethingelse)
   (else (displayln "error")))
 (cdr args))

我怎么能做这样的事情？

Answer 1

使用unquote-splicing（又名,@）删除map周围的列表。

例子：

(define xs '(a b c))
`(1 2 ,xs  3 4)    ; => '(1 2 (a b c) 3 4)
`(1 2 ,@xs 3 4)    ; => '(1 2 a b c 3 4)

但是我注意到您在输入 stx 上使用了 syntax->datum 的语法转换器。这会删除词汇信息， 最终可能会导致问题。它建议使用syntax-case 或syntax-parse，它使用模式匹配来挑选元素 输入语法和模板以生成输出。

(define-syntax (choose stx)
  (syntax-case stx ()
    [(_choose args
              (datum fun-expr)
              ...)
     #'(apply (case (car args)
                [(datum) fun-expr]
                ...)
              (cdr args))]))

(define (run-it . xs) (list 'ran-it  xs))
(define (del-it . xs) (list 'delt-it xs))

(choose (list "run" 1 2 3)
        ("run" run-it)
        ("del" del-it))

Output: '(ran-it (1 2 3))