将 Excel 工作表导出到 Access db 宏

Question

经过一番搜索，我找到了一个宏，可以将 Excel 工作表导出为受密码保护的 Access 数据库中的记录

Dim cnn As ADODB.Connection 'dim the ADO collection class
Dim rst As ADODB.Recordset 'dim the ADO recordset class
Dim dbPath
Dim i As Long


'add error handling
On Error GoTo errHandler:

'Variables for file path and last row of data
dbPath = ("\\serverpath\reporting.accdb")
'Initialise the collection class variable
Set cnn = New ADODB.Connection

cnn.Open "Provider=Microsoft.ACE.OLEDB.12.0;Data Source=" & dbPath, , "password"

Set rst = New ADODB.Recordset 'assign memory to the recordset

rst.Open Source:="table", ActiveConnection:=cnn, _
CursorType:=adOpenDynamic, LockType:=adLockOptimistic, _
Options:=adCmdTable

rst.AddNew
For i = 1 To 180
    rst(Cells(1, i).Value) = Cells(nextrow, i).Value
Next i
rst.Update

'close the recordset
rst.Close
' Close the connection
cnn.Close
'clear memory
Set rst = Nothing
Set cnn = Nothing

'communicate with the user
MsgBox " The data has been successfully sent to the access database"

'Update the sheet
Application.ScreenUpdating = True

On Error GoTo 0
Exit Sub
errHandler:

'clear memory
Set rst = Nothing
Set cnn = Nothing
MsgBox "Error " & Err.Number & " (" & Err.Description & ") in procedure Export_Data"

我在cnn.Open 收到错误“错误 2147217843 工作组信息文件丢失”

Answer 1

该错误消息具有误导性。问题不在于 MDW（工作组信息文件）。

Access 数据库有两种密码：

1. 与个人 Access 安全用户帐户关联的密码
2. 适用于数据库本身的密码，所有用户都必须提供该密码才能打开数据库

您的密码是第二种类型，但您的连接尝试将其视为第一种类型。

在连接字符串中使用Jet OLEDB:Database Password 选项。

Dim strConnect As String
strConnect = "Provider=Microsoft.ACE.OLEDB.12.0;Data Source=" & _
    dbPath & ";Jet OLEDB:Database Password='password';"
Debug.Print strConnect
cnn.Open strConnect

Answer 2

您可以尝试传递有关工作组文件的信息，但我认为它主要用于 mdb 文件：

Provider=Microsoft.Jet.OLEDB.12.0;Data Source=D:\Test\Test.accdb;User ID=Admin;Jet OLEDB:System database=D:\Test\System.mdw;