Excel 检测并跟踪任何工作表中的（值）变化

Question

我设法编写了一个代码来检测任何工作表中特定单元格的值变化，但我一直在努力构建检测和跟踪范围（值）变化的东西。

例如，如果用户决定复制和粘贴某个范围的数据（比如说超过 1 个单元格），它不会被宏捕获。用户选择一个范围，然后在仍然选择范围时手动将值输入到每个单元格中也是如此。

我当前的代码由 2 个宏构成，第一个在工作表选择发生更改时运行，并将 target.value 存储到以前的 value 变量中。第二个宏在工作表发生更改时运行，并测试目标值是否与前一个不同，如果是，则通知用户已发生的更改。

Answer 1

好的，我在这里看不到任何涵盖整个事情的东西，所以这是一个粗略的尝试。

它将处理单个或多个单元格更新（您可以设置一些您不想超过的限制...）

它不会处理多区域（非连续）范围更新，但可以扩展来处理。

您可能还应该添加一些错误处理。

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim Where As String, OldValue As Variant, NewValue As Variant
    Dim r As Long, c As Long

    Dim rngTrack As Range

    Application.EnableEvents = False
    Where = Target.Address
    NewValue = Target.Value
    Application.Undo
    OldValue = Target.Value 'get the previous values
    Target.Value = NewValue
    Application.EnableEvents = True

    Set rngTrack = Sheets("Tracking").Cells(Rows.Count, 1).End(xlUp).Offset(1, 0)

    'multi-cell ranges are different from single-cell ranges
    If Target.Cells.CountLarge > 1 And Target.Cells.CountLarge < 1000 Then
        'multi-cell: treat as arrays
        For r = 1 To UBound(OldValue, 1)
        For c = 1 To UBound(OldValue, 2)
            If OldValue(r, c) <> NewValue(r, c) Then
                rngTrack.Resize(1, 3).Value = _
                  Array(Target.Cells(r, c).Address, OldValue(r, c), NewValue(r, c))
                Set rngTrack = rngTrack.Offset(1, 0)
            End If
        Next c
        Next r
    Else
        'single-cell: not an array
        If OldValue <> NewValue Then
            rngTrack.Resize(1, 3).Value = _
              Array(Target.Cells(r, c).Address, OldValue, NewValue)
            Set rngTrack = rngTrack.Offset(1, 0)
        End If
    End If

End Sub

获取先前值的“撤消”部分来自 Gary's Student's answer here： Using VBA how do I detect when any value in a worksheet changes?

Answer 2

这个 subs 会为你工作，但你只是在每张表中手动实现代码。只需要复制粘贴。请参阅下面的截图，这是一张Sheet1

(1) 声明一个公共变量。

Public ChangeTrac As Variant

(2) 在 Worksheet_SelectionChange 事件中编写以下代码

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    ChangeTrac = Target.Value
End Sub

(3) 在 Worksheet_Change 事件中编写以下代码

Private Sub Worksheet_Change(ByVal Target As Range)
    If Not Application.Intersect(Target, Cells()) Is Nothing Then
        If ChangeTrac <> Target.Value Then
            MsgBox "Value changed to Sheet1 " & Target.Address & " cell."
            Range(Target.Address).Select
        End If
    End If
End Sub

然后通过更改任何单元格中的数据进行测试。如果任何单元格值发生更改，它会提示。