使用命名变量运行 asm 程序时延迟

Question

我有以下程序将两个数字相乘：

.globl main

main:
    # Store the two numbers temporarily in ebx, ecx
    mov $7,     %ebx
    mov $14,     %ecx
    # clear out eax and add ebx (7) to it ecx (14) times
    mov $0,     %eax
multiply_step:
    add %ebx,   %eax
    dec %ecx
    jnz multiply_step
    ret

但是，如果我为 14 和 7 添加变量，无论出于何种原因，程序运行大约需要一秒钟，这似乎有点奇怪（上面的程序是瞬时的）--

.globl main
.globl x,y
x:  .byte 7
y:  .byte 14

main:
    mov x,     %ebx
    mov y,     %ecx
    mov $0,     %eax
multiply_step:
    add %ebx,   %eax
    dec %ecx
    jnz multiply_step
    ret

为什么这个程序需要更长的时间才能运行？我将两者都调用为：

$ gcc m2.s -o m2 && ./m2; echo $?
# 98

Answer 1

变量 x 是一个字节，但是您将 4 个字节移动到 ebx，所以 ebx 没有值 7。加载到 ebx 的实际值是 0x1d8b0e07。同样，ecx 中的值类似于 0x011d8b0e，因此您可以看到为什么您的循环比 0x0e 时花费的时间长得多。

尽管有这个错误，但结果的低字节是一样的。

要将这些字节值加载到 32 位寄存器中，请使用：

movzbl x, %ebx
movzbl y, %ecx

该指令从内存中读取一个字节，将其零扩展为 32 位，并将结果放入目标寄存器。

或者在 64 位代码中，就像您在其他问题中使用的那样，RIP 相对寻址更有效，并且可以在现代 PIE 可执行文件中工作：

movzbl x(%rip), %ebx
movzbl y(%rip), %ecx