Neo4j Cypher 查询，用于根据特征增量查找节点

Question

在我的 Neo4j/Spring Data Neo4j 4 项目中，我有一个实体：Product

每个 Product 都有一个 Integer 属性 - price

例如，我有以下产品的价格：

Product1.price = 100
Product2.price = 305
Product3.price = 10000
Product4.price = 1000
Product5.price = 220

产品之间没有关系。

我需要根据初始价格值（Cypher 查询参数）找到一组通过最大价格增量（Cypher 查询参数）相互区分的产品（路径）。

例如，我需要在 Neo4j 数据库中查找从 price = 50 和 price delta = 150 开始的所有产品。作为输出，我希望得到以下产品：

Product1.price = 100
Product5.price = 220
Product2.price = 305

计算如下：

起始价格 = 50，因此第一个产品的价格应不低于 50 且不高于 200（50+150）。因此，基于此，我们从目录中找到了价格 = 100 的产品。第二个产品的价格应不低于 100 且不超过 250（100+150）.. 这个产品的价格 = 220..第三个价格不低于220不超过370。这是价格= 305的产品

能否请您显示一个可以找到此类产品的 Cypher 查询。

Answer 1

作为一种替代解决方案，它的查询速度应该更快，但需要更多的维护和保养才能保持正常工作（尤其是在产品价格数据快速变化的情况下），您可以在产品节点之间按价格升序创建关系，并保持增量作为关系属性。

您可以通过以下方式使用 APOC 程序创建它：

MATCH (p:Product)
WITH p 
ORDER BY p.price ASC
WITH apoc.coll.pairsMin(COLLECT(p)) as products
UNWIND products as prodPairs
WITH prodPairs[0] as prod1, prodPairs[1] as prod2
CREATE (prod1)-[r:NextProd]->(prod2)
SET r.delta = prod2.price - prod1.price

设置完成后，您可以通过以下方式查询它。

WITH {startPrice:50, delta:150} as params
WITH params, params.startPrice + params.delta as ceiling
MATCH (start:Product)
WHERE params.startPrice <= start.price <= ceiling
WITH start, params
ORDER BY start.price ASC
LIMIT 1
MATCH (start)-[r:NextProd*0..]->(product:Product)
WHERE ALL(rel in r WHERE rel.delta <= params.delta)
RETURN DISTINCT product

这应该是一个相当快的查询，因为 ALL() 谓词应该在它达到超过所需增量的关系时切断变量匹配。

当然，缺点是您需要确保会影响此链表结构的每个操作（添加或删除产品以及更改产品价格）都正确调整结构，并且您可能需要考虑锁定方法确保线程安全，这样您就不会在产品和/或价格同时更新时破坏链接列表。

Answer 2

这在 Cypher 中执行起来相当复杂。我想到的唯一方法是使用 REDUCE() 函数和 CASE 语句，如果产品在列表中最后一个产品的价格增量范围内，则有条件地将产品添加到列表末尾。

请记住，使用这种方法无法使产品的处理过程短路。如果总共有 100 万个产品，并且我们在产品的有序列表中发现只有前两个产品在该增量模式内，则此查询将继续检查这百万个产品中的每一个剩余产品，尽管它们都不会添加到我们的列表中。

这个查询应该适合你。

WITH {startPrice:50, delta:150} as params
MATCH (p:Product)
WHERE p.price >= params.startPrice
WITH params, p
ORDER BY p.price asc
WITH params, COLLECT(p) as products
WITH params, TAIL(products) as products, HEAD(products) as first
WHERE first.price <= params.startPrice + params.delta
WITH REDUCE(prods = [first], prod in products | 
  CASE WHEN prod.price <= LAST(prods).price + params.delta 
       THEN prods + prod 
       ELSE prods END) as products
RETURN products

Answer 3

解决方案需要在迭代期间传输中间结果。一个有趣的问题，因为今天 cypher 并没有直接提供这种可能性。作为练习（草图），使用来自APOC-library 的apoc.periodic.commit 过程：

CALL apoc.create.uuid() YIELD uuid
CALL apoc.periodic.commit("
  MERGE (H:tmpVars {id: {tmpId}})
  ON CREATE SET H.prices = [],
                H.lastPrice = {lastPrice}, 
                H.delta = {delta} 
  WITH H
  MATCH (P:Product) WHERE P.price > H.lastPrice AND 
                          P.price < H.lastPrice + H.delta
  WITH H, max(P.price) as lastPrice
  SET H.lastPrice = lastPrice, 
      H.prices = H.prices + lastPrice
  RETURN 1
  ", {tmpId: uuid, delta: 150, lastPrice: 50}
) YIELD updates, executions, runtime
MATCH (T:tmpVars {id: uuid}) 
WITH T, T.prices as prices DETACH DELETE T
WITH prices 
UNWIND prices as price
MATCH (P:Product) WHERE P.price = price
RETURN P ORDER BY P.price ASC