检查字符串/文件夹名是否包含特定字符 X 次

Question

我正在尝试制作一个批处理文件：

• 查找包含特定文件 (_extern.inf) 的所有文件夹
• 检查文件夹名称是否正好包含 X 个分隔符。否则忽略文件（即，如果文件夹名称不是预期格式，则忽略文件夹）
• 用分隔符分割文件夹名称，并使用其中一个子字符串来制作将文件夹移动到的路径

除了支票之外，我一切正常。 我见过Batch File Count all occurrences of a character within a string，但它似乎对我不起作用（%count% 为空）。我猜是因为嵌套的 for 循环。 似乎打破不符合文件的循环也不是微不足道的......

我想检查%%~ni 是否包含%expect_delims% 出现的%delim%。如果没有继续下一个文件夹。

@echo off
REM No trailing spaces!
set "infolder=input_path"
set "outfolder=output_path"
set "delim=_"
set "expect_delims=2"


REM Resursively look for folders with _extern.inf files
for /d /r "%infolder%" %%i in (*) do  @if exist %%i\_extern.inf (

    REM echo the folder is %%i


    REM tokens decide which part to take of the split string.
    REM "tokens=1,3" would take first and third and make %%b available

    for /F "tokens=1 delims=%delim%" %%a in ("%%~ni") do (

        REM Create project folder if doesn't exist
        if not exist "%outfolder%\%%a.raw\Data\" (
            echo creating folder %outfolder%\%%a.raw\Data
            mkdir "%outfolder%\%%a.raw\Data"
        )

        REM move folder if doesn't exist
        if exist "%outfolder%\%%a.raw\Data\%%~nxi" echo raw folder already exists!

        if not exist "%outfolder%\%%a.raw\Data\%%~nxi" (
            echo Moving "%%~fi" to "%outfolder%\%%a.raw\Data\%%~nxi"
            move "%%~fi" "%outfolder%\%%a.raw\Data\%%~nxi"
        )
    )

)

Answer 1

根据@aschipfl 的想法，我找到了一种让它发挥作用的方法。

跨块边界传输变量基于：Windows batch setlocal enabledelayedexpansion call return value

@echo off

REM ****** SETTINGS ******
REM No trailing spaces!
set "infolder=input_dir"
set "outfolder=output_dir"
set "delim=_"
set "expect_delims=4"


REM SCRIPT STARTS HERE
setlocal
set /a "token_start=%expect_delims%+1"
set /a "token_end=%expect_delims%+2"


REM Resursively look for folders with _extern.inf files
for /d /r "%infolder%" %%i in (*) do  @if exist %%i\_extern.inf (

    echo ****** Start processing ******
    echo File: "%%~i"


    for /F "tokens=1,%token_start%,%token_end% delims=%delim%" %%a in ("%%~ni") do (
        REM echo the raw folder is %%i
        if "%%b" == "" (echo Filename check: Too few delimiters. File ignored.) else (
            if not "%%c" == "" (echo Filename check: Too many delimiters. File ignored.) else (

                echo Filename check: OK

                REM Create project folder if doesn't exist
                if not exist "%outfolder%\%%a.raw\Data" (
                    echo creating folder "%outfolder%\%%a.raw\Data"
                    mkdir "%outfolder%\%%a.raw\Data"
                )

                REM move raw folder if doesn't exist
                if exist "%outfolder%\%%a.raw\Data\%%~nxi" echo raw folder already exists! File ignored.

                if not exist "%outfolder%\%%a.raw\Data\%%~nxi\" (
                    echo Moving "%%~fi" to "%outfolder%\%%a.raw\Data\%%~nxi"
                    move  "%%~fi" "%outfolder%\%%a.raw\Data\%%~nxi"
                )

            )    
        )

        echo ****** End processing ******
        echo.
    )



)