我有一个按时间排序的三维点列表。有没有办法绘制点，以便我可以获得视觉表示，其中还包括有关点在列表中出现位置的信息？我最初的想法是找到一种按绘制顺序为点着色的方法。
ListPlot3D 将一张纸覆盖在这些点上，而不考虑它们的绘制顺序。
ListPointPlot 只显示点，但没有说明它们的绘制顺序。正是在这里，我正在考虑根据它们在列表中出现的顺序对点进行着色。
ListLinePlot 似乎没有 3D 表亲，这与许多其他绘图功能不同。
【问题讨论】：
你也可以这样做
lst = RandomReal[{0, 3}, {20, 3}];
Graphics3D[{Thickness[0.005],
Line[lst,
VertexColors ->
Table[ColorData["BlueGreenYellow"][i], {i,
Rescale[Range[Length[lst]]]}]]}]
【讨论】：
由于您没有提供示例，我通过创建 3d 自动回避随机游走来编造一些示例：
Clear[saRW3d]
saRW3d[steps_]:=
Module[{visited},
visited[_]=False;
NestList[
(Function[{randMove},
If[
visited[#+randMove]==False,
visited[#+randMove]=True;
#+randMove,
#
]
][RandomChoice[{{1,0,0},{-1,0,0},{0,1,0},{0,-1,0},{0,0,1},{0,0,-1}}]])&,
{0,0,0},
steps
]//DeleteDuplicates
]
（这有点麻烦，但可以完成工作；它会在 3d 中生成随机游走，从而避免自身，即避免在后续步骤中重新访问相同的地方）。
然后我们像这样产生 100000 步
dat = saRW3d[100000];
这就像我理解您的数据点一样。然后我们根据它是哪一步来改变颜色：
datpairs = Partition[dat, 2, 1];
len = Length@datpairs;
dressPoints[pts_, lspec_] := {RGBColor[(N@First@lspec)/len, 0, 0],
Line@pts};
datplt = MapIndexed[dressPoints, datpairs];
这也可以像其他答案一样一次性完成
datplt=MapIndexed[
{RGBColor[(N@First@#2)/Length@dat, 0, 0], Line@#1} &,
Partition[dat, 2, 1]
]
但我倾向于避免这种结构，因为我发现它们更难阅读和修改。
最后绘制结果：
Graphics3D[datplt]
随着时间的推移，路径会变得越来越红。
如果这是你所追求的，我可以详细说明。
编辑：可能有更简单的方法来做到这一点......
EDIT2：显示大量点以证明在 arrows 不易扩展的情况下及时查看定性趋势非常有用。
EDIT3：添加了单行版本。
【讨论】：
我认为 Heike 的方法是最好的，但恕我直言，她把它弄得太复杂了。我会使用：
Graphics3D[{
Thickness[0.005],
Line[lst,
VertexColors ->
ColorData["SolarColors"] /@ Rescale@Range@Length@lst ]
}]
（acl的数据）
【讨论】：
Graphics3D@(Arrow /@ Partition[RandomInteger[{0, 10}, {10, 3}], 2, 1])
【讨论】：
关于你的最后一个问题：如果你想要一种ListLinePlot3D 而不是ListPointPlot，你可以简单地执行以下操作：
pointList =
Table[{t, Sin[t] + 5 Sin[t/10], Cos[t] + 5 Cos[t/10],
t + Cos[t/10]}, {t, 0, 100, .5}];
ListPointPlot3D[pointList[[All, {2, 3, 4}]]] /. Point -> Line
当然，通过这种方式你不能设置线属性，所以如果你想的话，你必须稍微改变一下规则：
ListPointPlot3D[pointList[[All, {2, 3, 4}]]] /.
Point[a___] :> {Red, Thickness[0.02], Line[a]}
或与
ListPointPlot3D[pointList[[All, {2, 3, 4}]]] /.
Point[a___] :> {Red, Thickness[0.002], Line[a], Black, Point[a]}
但是，为什么不只使用 Graphics3D 和一些图形基元呢？
【讨论】：