如何从命令行评估笔记本？

Question

我们如何从命令行评估 Mathematica 笔记本（即在命令行模式下运行内核时）？

假设我们在远程机器上工作。我知道可以将笔记本转换为 m 文件并对其进行评估，但我很好奇是否可以直接使用笔记本进行此操作。

---

这是我目前所拥有的：

首先，we need to start a headless X server 在远程 Linux 机器上，这样前端就可以在那里运行（并打开笔记本）。如果您在本地计算机上工作，请跳过此步骤。

Xvfb :1 &
export DISPLAY=:1

在此之后，我启动了一个 Mathematica 内核 (math) 并执行了以下操作。

必须使用UsingFrontEnd，因为打开笔记本需要前端。 test.nb 有一个包含a=1 的输入单元格。

In[1]:= nb=UsingFrontEnd@NotebookOpen["test.nb"]

Out[1]= -NotebookObject-

在尝试评估笔记本后，显然我得到了dialog，我需要使用Return[] 才能返回。我不确定为什么输入行再次从 1 开始计数（前端启动了新内核？）请注意，a 没有获得值。

In[2]:= UsingFrontEnd@NotebookEvaluate[nb]

 In[1]:= a

 Out[1]= a

 In[2]:= Return[]

Out[2]= a

从对话框返回后，a 仍然没有值。

In[3]:= a

Out[3]= a

Answer 1

这是对您问题的部分回答。以下代码打开一个笔记本，为其分配一个 “测试”内核，评估该内核中的笔记本，等待评估完成并 保存评估的笔记本。它确实不会导致a 在本地命令行内核中定义。

这将等待笔记本中的内核评估完成：

NotebookPauseForEvaluation[nb_] := Module[{},
 While[ NotebookEvaluatingQ[nb], Pause[.25] ] ]

这会检查笔记本中的任何单元格是否仍在评估中：

NotebookEvaluatingQ[nb_]:=Module[{},
 SelectionMove[nb,All,Notebook];
 Or@@Map["Evaluating"/.#&,Developer`CellInformation[nb]]
]

这只是一条诊断消息，当您尝试重新定义像“测试”这样的内核时：

AddTestEvaluator::exists = "Evaluator `1` is already defined, but has a definition that is `2` and not the expected `3`.";

这是向前端添加评估器的代码，例如“测试”：

AddTestEvaluator[evaluator_String] := Module[
 {evaluatornames, testevaluator},
 evaluatornames = EvaluatorNames /. Options[$FrontEnd, EvaluatorNames];
 testevaluator = evaluator -> {"AutoStartOnLaunch" -> False};
 Which[
  MemberQ[evaluatornames, evaluator -> {"AutoStartOnLaunch" -> False}],
  Null,
  MemberQ[evaluatornames, evaluator -> _],
  Message[AddTestEvaluator::exists,
  evaluator,
  evaluator /. (EvaluatorNames /. Options[$FrontEnd, EvaluatorNames]),
  {"AutoStartOnLaunch" -> False}
 ],
 True,
 AppendTo[evaluatornames, testevaluator];
 SetOptions[$FrontEnd, EvaluatorNames -> evaluatornames]
 ]
]

最后，这是在“测试”内核下评估笔记本并保存评估内核的代码：

 UsingFrontEnd[     
  AddTestEvaluator["Test"];
  nb = NotebookOpen["test.nb"];
  SetOptions[nb,Evaluator->"Test"];
  SelectionMove[nb,All,Notebook];
  SelectionEvaluate[nb];
  NotebookPauseForEvaluation[nb];
  NotebookSave[nb]
 ]

我仍在为您的全部问题寻找解决方案（在本地命令中定义了 a 行内核）。

Answer 2

这是在 Windows 上，使用 Arnouds 做得很好，只是添加了普通的旧 MathLink（顺便说一句相当慢......）：

link = LinkCreate["8000", LinkProtocol -> "TCPIP"];
UsingFrontEnd[
NotebookPauseForEvaluation[nb_] := Module[{},
 While[ NotebookEvaluatingQ[nb], Pause[.25] ] ];
NotebookEvaluatingQ[nb_]:=Module[{},
 SelectionMove[nb,All,Notebook];
 Or@@Map["Evaluating"/.#&,Developer`CellInformation[nb]]
];
nb = NotebookOpen["G:\\mma\\test.nb"];
SelectionMove[nb, Before, Notebook];
NotebookWrite[nb, Cell["Link = LinkConnect[\"8000\", LinkProtocol -> \"TCPIP\"]", "Input"]];
SelectionMove[nb, After, Notebook];
NotebookWrite[nb, Cell["LinkWrite[Link, a]", "Input"]];
SelectionMove[nb, All, Notebook];
SelectionEvaluate[nb];
a = LinkRead[link];
Print["a = ",a];
]