SAS 数组/循环迭代变量

Question

这是我第一次在这个论坛上提问。我已经使用 SAS/Proc SQL 大约 4 年了，但我不是代码绝地，所以请给出详细的答案，并且对数组相当陌生，所以如果我的问题没有详细/解释，请原谅。一般来说，我对构建/使用简单的数组感到 100% 的舒适。但是我有一个非常具体的挑战，我无法弄清楚......很难用语言表达，所以这可能会变得冗长但这里......

对于我要完成的工作的基本理解，它有点类似于简单的贷款摊销，其中第 1 个月的余额是原始贷款金额，比如说 10,000 美元，第 2 个月的余额是 orig_ln_amt 减去任何新的本金/利息支付减去任何额外的付款，可以说是 9500 美元，第 3 个月的结果是 9000 美元等等。对于 1 个帐户来说很容易，但我正在构建一个数组，当所有活动帐户汇总在一起时，我实际上会给出预测的总剩余余额未来一个月，所以我使用的数组大小每个月都会根据帐户的年龄而变化。

下面是一些我希望可以工作的示例代码：

DATA SAMPLE;
  SET INPUT_DATA; 'HAS EACH OF THE 3 INPUT ARRAYS LAID OUT SIDE BY SIDE BY SIDE
  ARRAY_ONE {193} ARRAY_ONE1-ARRAY_ONE193; 
  ARRAY_TWO {97} ARRAY_TWO1-ARRAY_TWO97;
  ARRAY_THREE {97} ARRAY_THREE1-ARRAY_THREE97; 
  OUTPUT_ARRAY {193} OUTPUT_ARRAY1-OUTPUT_ARRAY193; 'PORTFOLIO BALANCE EACH FUTURE MONTH
  DO I = 1 TO 193;
    OUTPUT_ARRAY[I] = sum(of ARRAY_ONE[I]-ARRAY_ONE193) - sum(of ARRAY_TWO[I]-ARRAY_TWO97) - sum(of ARRAY_THREE[I]-ARRAY_THREE97);
  END;
RUN;

问题是 SAS 不喜欢数组计算中的 [I[ 迭代引用。我也尝试过 &I 基于另一个在线用户收到的似乎是类似问题的解决方案。这个逻辑是有道理的，看起来它应该在理论上可行，但不是......

因此，我们不得不手动操作和编码 193 个计算中的每一个：

OUTPUT_ARRAY1 = sum(of ARRAY_ONE1-ARRAY_ONE193) - sum(of ARRAY_TWO1-ARRAY_TWO97) - sum(of ARRAY_THREE1-ARRAY_THREE97);
OUTPUT_ARRAY2 = sum(of ARRAY_ONE2-ARRAY_ONE193) - sum(of ARRAY_TWO2-ARRAY_TWO97) - sum(of ARRAY_THREE2-ARRAY_THREE97);
  ...
OUTPUT_ARRAY97 = sum(of ARRAY_ONE97-ARRAY_ONE193) - sum(of ARRAY_TWO97-ARRAY_TWO97) - sum(of ARRAY_THREE97-ARRAY_THREE97);
OUTPUT_ARRAY98 = sum(of ARRAY_ONE98-ARRAY_ONE193);
  ...
OUTPUT_ARRAY193 = sum(of ARRAY_ONE193-ARRAY_ONE193);

似乎应该有一个简单的解决方案，但我们无法弄清楚。提前感谢大家可以提供的任何帮助。

Answer 1

所以你有三组对原则进行调整的变量。您有一个起始余额，并且您想通过应用调整来计算各种中间余额。

首先通过使数组大小相同来简化您的问题。新变量将丢失。如果您实际上有这些变量，但只是不想将它们包含在计算中，则将它们从输入数据集中删除。请注意，如果您有名为 ONE1 到 ONE193 的变量，那么您可以通过使用此语句 array one(193); 创建一个名为 ONE 的数组来使用这些变量。

第二次简化你的算术以更接近你的问题描述。在我看来，算法是下一个余额是基于前一个余额减去所有调整。包括零以处理所有调整都缺少值的情况。

%let n=193;
data want;
  set have;
  array one (&n);
  array two (&n);
  array three (&n);
  array balance Initial_balance balance1-balance&n;
  do i=1 to dim(balance)-1;
    balance(i+1)=balance(i)-sum(0,one(i),two(i),three(i));
  end;
run;

Answer 2

像VAR1-VAR20 这样的变量列表是在编译数据步骤时计算的。您尝试使用ARRAY[I]-variable193 作为变量列表不会成功。只需使用另一个 DO 循环即可。

DO I = 1 TO dim(output_array);
  output_array(i)=0;
  DO J=I to dim(array_one);
    output_array(i)= sum(output_array(i),array_one(j));
  END;
  DO J=I to dim(array_two);
    output_array(i)= sum(output_array(i),array_two(j));
  END;
  DO J=I to dim(array_three);
    output_array(i)= sum(output_array(i),array_three(j));
  END;
END;