在具有 2003 ISO C 绑定的 Visual Studio 2010 中从 Fortran 调用 C++ 函数

Question

我必须从我的 fortran 程序中调用一个 C++ 函数。我正在使用 Visual Studio 2010。我阅读了本书 http://www.amazon.com/Guide-Fortran-Programming-Walter-Brainerd/dp/1848825420 中有关 2003 ISO C 绑定的相关章节。我试图编译并运行第 219 页的简单示例（我在下面复制了它），但它显示“错误 LNK2019：未解析的外部符号 _c 在函数 _MAIN__ 中引用”。这些是我遵循的步骤。

1)我用Fortran主程序和模块创建了一个Fortran项目，并将其设置为“启动项目”。

2)我创建了一个“静态库”类型的 C++ 项目。

3）我添加了 $(IFORT_COMPILERvv)\compiler\lib\ia32 ，正如此处http://software.intel.com/en-us/articles/configuring-visual-studio-for-mixed-language-applications 所解释的那样

当我编译时，我得到了那个错误。如果我评论 Call C 行，它会完美运行，所以它找不到 C 函数。有什么建议吗？提前致谢。以下是 C 和 Fortran 代码：

    module type_def
       use, intrinsic :: iso_c_binding
       implicit none
       private

       type, public, bind(c) :: t_type
          integer(kind=c_int) :: count
          real(kind=c_float) :: data
       end type t_type
    end module type_def

    program fortran_calls_c
       use type_def
       use, intrinsic :: iso_c_binding
       implicit none

       type(t_type) :: t
       real(kind=c_float) :: x, y
       integer(kind=c_int), dimension(0:1, 0:2) :: a

       interface
          subroutine c(tp, arr, a, b, m) bind(c)
             import :: c_float, c_int, c_char, t_type
             type(t_type) :: tp
             integer(kind=c_int), dimension(0:1, 0:2) :: arr
             real(kind=c_float) :: a, b
             character(kind=c_char), dimension(*) :: m
          end subroutine c
       end interface

       t = t_type(count=99, data=9.9)
       x = 1.1
       a = reshape([1, 2, 3, 4, 5, 6], shape(a))
       call c(t, a, x, y, "doubling x" // c_null_char)
       print *, x, y
       print *, t
       print *, a

    end program fortran_calls_c

    #include "stdafx.h"
    //#include <iostream>
    #include <fstream>
    typedef struct {int amount; float value;} newtype;
    void c(newtype *nt, int arr[3][2], float *a, float *b, char msg[])
    {
        printf (" %d %f\n", nt->amount, nt->value);
        printf (" %d %d %d\n", arr[0][1], arr[1][0], arr[1][1]);
        printf (" %s\n", msg);
        *b = 2*(*a);
    }

Answer 1

现已编辑答案以反映 IanH 评论中的建议和知识：

正如@BoBTFish 建议的那样，将extern "C" 插入C++ 函数c 的声明中。当然，请确保您使用大写字母 C，那里的一些评论有点松散。

我注释掉了包含stdafx.h 的源代码行，这似乎是可选的，我懒得寻找或创建它。

在那之后，对于 Fortran 项目，

• 链接器/常规/附加库目录到lib文件所在的目录；和
• 链接器/输入/附加依赖项指定lib文件。

将 C++ 和 Fortran 项目的运行时库选项设置为相同。在 Fortran 项目的属性页面中，将 Fortran / Libraries 设置为 Debug Multithread DLL。

现在它编译并执行并生成以下内容：

 99 9.900000
 2 3 4
 doubling x
   1.100000       2.200000
          99   9.900000
           1           2           3           4           5           6

感谢 IanH 的投入，我现在是一个更明智的脚本跟随猴子。