函数更新 kdb 中的多个列

Question

我有一张表要更新：

q)show table:([]letter:`a`b`c`a;fruit:`apple`banana`pear`strawberry;family:`mom`dad`brother`sister)
letter fruit      family
-------------------------
a      apple      mom
b      banana     dad
c      pear       brother
a      strawberry sister

我想用它们各自列的名称替换所有条目。

这似乎有效：

q){![table;();0b;(enlist x)!(enlist `x)]}`letter
letter fruit      family
-------------------------
letter apple      mom
letter banana     dad
letter pear       brother
letter strawberry sister

...但不是这个：

q){![table;();0b;(enlist x)!(enlist `x)]}`letter`fruit
'type
  [1]  {![table;();0b;(enlist x)!(enlist `x)]}
        ^
q))

目的是创建一个为分类变量创建虚拟变量的函数，所以我需要一个通用函数。有什么建议吗？

Answer 1

这可以通过@ apply 来实现，而不是像这样的功能更新：

q){@[`table;x;:;x]}`letter`fruit
`table
q)table
letter fruit family
--------------------
letter fruit mom
letter fruit dad
letter fruit brother
letter fruit sister

编辑 - 对于所有列：

{@[`table;x;:;x]} each cols table

或

{@[x;y;:;y]}/[table;cols table]

q)table
letter fruit family
-------------------
letter fruit family
letter fruit family
letter fruit family
letter fruit family

Answer 2

您原来的功能更新可以这样工作：

q){![table;();0b;x!enlist'[x:(),x]]}cols table
letter fruit family
-------------------
letter fruit family
letter fruit family
letter fruit family
letter fruit family