如何使用 VBA 对按钮进行编码？

Question

我有一个按钮的 vba 脚本，它在我的工作簿的每个工作表上放置一个按钮。我想对这些按钮进行编程，以便每次按下它们时，它们都会调用一个打印脚本，该脚本将在工作表上打印信息。这是我的按钮代码：

Sub AddButtons()
    Dim ws As Excel.Worksheet
    Dim btn As Button

    For Each ws In ThisWorkbook.Worksheets
        Set btn = ws.Buttons.Add(625, 0, 50, 25)
        Call pageprintTEST1(ws)
    Next ws
End Sub

这是我的打印脚本代码：

Sub pageprintTEST1(ws As Excel.Worksheet)
 Application.Dialogs(xlDialogPrinterSetup).Show
         Worksheets(ws).Activate
   With ActiveWorkbook.Worksheets(ws).PageSetup
        .PrintArea = "A1:O48"
        .Orientation = xlLandscape
        .Zoom = False
        .FitToPagesTall = 1
        .FitToPagesWide = 1
    End With
    ActiveWorkbook.Worksheets(ws).PrintOut

我在这方面遇到了一些问题。首先，此脚本为每张纸添加按钮，我只希望从第 5 页开始将按钮添加到工作表（因此前 4 张纸上没有按钮）。其次，它不会等我在打开打印机对话框之前单击按钮，一旦您选择了打印机，它就会显示错误不匹配。

我研究了如何将变量传递给不同的 subs 和 call 方法，这似乎是正确的，但现在我不确定我哪里出错了。如果有人有任何建议或知道该怎么做，我将不胜感激！

Answer 1

您需要使用按钮的OnAction 属性来存储宏名称，但不能将对象变量传递给它。由于该按钮只有在其工作表处于活动状态时才能被单击，因此您可以这样使用：

Sub AddButtons()
    Dim btn As Button
    Dim n As Long

    For n = 5 To ThisWorkbook.Worksheets.Count
        Set btn = ThisWorkbook.Worksheets(n).Buttons.Add(625, 0, 50, 25)
        btn.OnAction = "pageprintTEST1"
    Next
End Sub

Sub pageprintTEST1()
 Application.Dialogs(xlDialogPrinterSetup).Show
   With ActiveSheet.PageSetup
        .PrintArea = "A1:O48"
        .Orientation = xlLandscape
        .Zoom = False
        .FitToPagesTall = 1
        .FitToPagesWide = 1
    End With
    ActiveSheet.PrintOut
End Sub