运行大量 VBA 后出现打印预览问题

Question

我有一个 Excel 工作簿，其中几乎所有内容都是自动化的。它打开其他工作簿，从中复制数据，关闭它们，然后多次循环数据以生成我们打印和使用的报告。几乎每次运行所有 VBA 然后尝试打印后，打印预览都会卡住，要么找到打印机，要么加载图片中的页面大小。关闭 Excel 并重新打开文档会将打印预览恢复为正常功能。 VBA 所做的唯一与打印相关的事情就是更改打印区域。我对运行 VBA 的任何其他文档都没有这个问题。这只是一个错误还是代码中的某些东西？

这是导致打印预览无法以某种方式加载的代码。如果我跳过本节，那么它会按预期工作......我希望以某种方式让这个代码发挥作用，因为它仍然需要。

    Set wb1 = Workbooks.Open(FileName)
    Set wb2 = ThisWorkbook

    For i = LBound(sArray) To UBound(sArray) 'Loops through array, copies available data from last report
        ShtName = sArray(i, 0)
        On Error Resume Next
            wb1.Sheets(ShtName).Activate
            If Err.Number = 0 Then
                wb1.Sheets(ShtName).Activate
                Columns("A:U").Copy
                wb2.Sheets(ShtName).Activate
                Columns("BE:BV").Select
                Selection.PasteSpecial xlPasteValues
                Application.CutCopyMode = False
                lastrow = Cells(Rows.Count, "BE").End(xlUp).Row
                Range("BA2:BC2").Select
                Selection.AutoFill Destination:=Range(Cells(2, "BA"), Cells(lastrow, "BC")), Type:=xlFillDefault
            End If
        On Error GoTo 0

        DoEvents

    Next i

    wb1.Close False

    Sheet2.Activate

我尝试注释掉“On Error Resume Next”、“On Error Goto 0”、“If...”、“End If”和“DoEvents”。打印预览仍然失败，删除了那些，只是从上一张表中复制和粘贴。

Answer 1

看来删除DoEvents 的所有实例已经解决了这个问题...

打印预览工作正常，退出工作簿时 Excel 不再崩溃。

Answer 2

我相信您正在寻找某种类型的刷新操作，可以将预览显示与工作表上的数据重新同步。最后你可能想试试这个：

ActiveSheet.EnableCalculation = False  
ActiveSheet.EnableCalculation = True

如果这不起作用，请查看手动保存是否可以解决问题。您可以尝试在最后拨打Application.Save。

Answer 3

“当您选择文件 --> 打印时会自动进行打印预览。另一个选项是使用页面布局视图（状态栏右侧的图标）。要获得旧式打印预览，您需要使用 VBA。以下语句显示活动工作表的打印预览：ActiveSheet.PrintPreview"

引自 John Walkenbach 的 Microsoft Excel 2013 Power Programming with VBA，第 956-957 页。

话虽如此，我通过记录一个相对复杂的宏来测试您的问题，该宏创建一个新工作表，执行 25 个自动操作，并显示打印预览，然后在我单击 MsgBox 上的确定时关闭打印预览。我将程序迭代了 1000 次。我从来没有遇到过 PrintPreview 的问题。

Answer 4

这有点像在黑暗中拍摄，但我尝试稍微清理一下您的代码。看看这是否有任何影响。

Sub Test()

Dim wb1 As Workbook, wb2 As Workbook
Dim ws1 As Worksheet, ws2 As Worksheet
Dim isWS As Boolean

On Error GoTo sub_err

Set wb1 = Workbooks.Open(Filename)
Set wb2 = ThisWorkbook

For i = LBound(sArray) To UBound(sArray) 'Loops through array, copies available data from last report
    ShtName = sArray(i, 0)
    isWS = True
    Set ws1 = wb1.Sheets(ShtName)

    If isWS Then
        Set ws2 = wb2.Sheets(ShtName)

        ws1.Columns("A:U").Copy
        ws2.Columns("BE:BV").PasteSpecial xlPasteValues
        Application.CutCopyMode = False
        lastrow = ws2.Cells(ws2.Rows.Count, "BE").End(xlUp).Row
        ws2.Range("BA2:BC2").AutoFill Destination:=ws2.Range(ws2.Cells(2, "BA"), ws2.Cells(lastrow, "BC")), Type:=xlFillDefault
    End If
    DoEvents
Next i

wb1.Close False

ws2.Activate

sub_exit:
Exit Sub

sub_err:
If Err.Number = 9 Then
    isWS = False
    Resume Next
Else
    MsgBox "Error: " & Err.Number & vbNewLine & Err.Description
    Resume sub_exit
End If

End Sub

我所做的最重要的事情是分离了您的错误处理，这样只有当您在 wb1 中找不到工作表时它才会恢复，并且所有其他错误（无错误 9 错误）仍会显示您的错误消息。

我还确保您的所有 Range()、Cells() 和 Columns() 都引用了正确的工作表（以防 excel 变得混乱）并且我认为活动工作表是正确的工作表，但您可能想要在代码中验证这一点，以确保它在正确的工作表中执行正确的操作。

现在复制代码仅在isWS = true 时运行，并且除非抛出错误 9 代码，否则它将始终为真。我唯一不知道的是 wb2 是否总是有一个等于 ShtName 的工作表名称，但我猜它会因为它在你的 if err.number = 0 中。

我不确定这是否会为您带来任何改变，但我很想以其他方式听到您的结果。