使用 Perl 读取文件并插入变量

Question

我是 Perl 的新手，所以请坦白我的无知。我想要做的是读取一个文件（已经使用 File::Slurp 模块）并从文件中的数据创建变量。目前我有这个设置：

use File::Slurp;
my @targets = read_file("targetfile.txt");
print @targets;

在该目标文件中，我有以下数据：

身份证号：123456789

名称：anytownusa

1.2.3.4/32

5.6.7.8/32

第一行是 ID，第二行是名称，所有后续行都是 IP 地址（最大长度为几百）。

所以我的目标是读取该文件并创建如下所示的变量：

$var1="123456789";

$var2="anytownusa";

$var3="1.2.3.4/32,5.6.7.8/32,etc,etc,etc,etc,etc";

** 请注意，所有 IP 地址最终都会组合到一个变量中，并用 (,) 逗号分隔。

Answer 1

File::Slurp 将一次性读取完整的文件数据。如果文件很大，这可能会导致问题。让我向您展示解决此问题的简单方法。

1. 使用while循环逐行读取文件
2. 使用$.检查行号并将行数据分配给相应的变量
3. 将 ips 存储在数组中，最后使用 join 打印它们

注意：如果您必须更改行数据，请在将行数据分配给变量之前在相应的条件块中使用搜索和替换。

代码：

#!/usr/bin/perl
use strict;
use warnings;
my ($id, $name, @ips);

while(<DATA>){
    chomp;
    if ($. == 1){
        $id = $_;   
    }
    elsif ($. == 2){
        $name = $_;
    }
    else{
        push @ips, $_;  
    }
}

print "$id\n";
print "$name\n";
print join ",", @ips;

__DATA__
id: 123456789
name: anytownusa
1.2.3.4/32
5.6.7.8/32

Demo

Answer 2

正如已经指出的那样，没有理由将整个文件“slurp”变成一个变量。如果没有别的，它只会使处理更难。 另外，为什么不将命名标签存储在哈希中，在这个例子中

my %identity = (id => 123456789, name => 'anytownusa');

下面的代码从文件中提取键名，它们不是硬编码的。

然后

use warnings;
use strict;
use feature 'say';

my (@ips, %identity);

my $file = 'targetfile.txt';
open my $fh, '<', $file or die "Can't open $file: $!";

while (<$fh>) 
{
    next if not /\S/;
    chomp;

    my ($m1, $m2) = split /:/;                #/(stop bad syntax highlight)

    if ($m1 and $m2) { $identity{$m1} = $m2; }
    else             { push @ips, $m1;       }
}

say "$_: $identity{$_}" for keys %identity;

say join '/', @ips;

如果该行没有:，split 将返回整个行，这将是 ip，并存储在一个数组中以供以后处理。否则，它返回命名的对，用于'id' 和'name'。

我们首先跳过了next if not /\S/; 的空白行，因此该行必须有一些非空格元素并且else 就足够了，因为$m1 中总是有一些东西。我们还需要删除换行符，chomp。

Answer 3

直接将文件读入变量：

use Modern::Perl;

my ($id, $name, @ips) = (<DATA>,<DATA>,<DATA>);
chomp ($id, $name, @ips);
say $id;
say $name;
$" = ',';
say "@ips";

__DATA__
id: 123456789
name: anytownusa
1.2.3.4/32
5.6.7.8/32

输出：

id: 123456789
name: anytownusa
1.2.3.4/32,5.6.7.8/32