VHDL：是否可以同时移动数组元素？

Question

出于学习目的，我想创建自己的插入排序实现。 正如您现在可能看到的，其中一个步骤需要将数组元素向右移动 1。这里的主要困难是此操作的范围必须是动态的。

所以如果 sort_reg 是从 0 到 array_length 的数组，我需要实现 sort_reg(n)=i>=1，其中 m 范围的起始数组索引，从范围 (m 到 n-1) 到 (m+1 到 n) 将右移 1。

问题是是否有可能一步完成，然后怎么做？

Answer 1

是的，一步即可。您必须将元素存储在寄存器中，然后在同一上升沿为所有数组元素分配新值。

让我们用两个std_logic 类型的信号a 和b 做一个简单的例子。然后这个过程会在clock的上升沿交换两个元素：

process(clock)
begin
  if rising_edge(clock) then
    a <= b;
    b <= a;
  end if;
end process;

这是可行的，因为信号会在处理完成后获得新的值。因此，在分配b 时，分配了a 的旧值（在时钟上升沿之前）。

让我们继续您的示例。 你没有指定一个特定的数组，所以我拿这个：

type array_type is array(0 to SIZE-1) of std_logic_vector(7 downto 0);
signal sort_reg : array_type;

然后可以使用 for 循环编写该过程。 编辑：在每个迭代步骤中，if 语句可用于检查元素是否应实际移动。信号n 和m 应该是unsigned 类型（首选），或integer 类型，范围为0 到SIZE-1。 编辑 2：示例更改为 cmets 中所示的旋转。

-- value to insert in case of rotation
value_to_insert <= sort_reg(to_integer(n)); -- to_integer required if type of 'n' is unsigned

process(clock)
begin
  if rising_edge(clock) then
    -- This loop is unrolled by the synthesis tool.
    for i in SIZE-1 downto 1 loop
      -- shift elements [n-1:m] to [n:m+1]
      if (i <= n) and (i >= m+1) then
        sort_reg(i) <= sort_reg(i-1);
      end if;

      -- insert new value
      if i = m then
        sort_reg(i) <= value_to_insert;
      end if;
    end loop;

    -- insert into position zero
    if m = 0 then
      sort_reg(0) <= value_to_insert;
    end if;
  end if;
end process;

Answer 2

这个怎么样；

sort_reg <= sort_reg(1 to sort_reg'high) & sort_reg(0);

我假设sort_reg 是一个定义为的信号；

signal sort_reg : some_array_type(0 to N);

在这种情况下，sort_reg'high 是一个等于 N 的属性。

在 vhdl 中，& 用作连接运算符。它将两个向量/数组连接在一起形成一个向量/数组。

以上示例仅移动 1 个项目。如果你想通过M移动，你可以使用这样的东西；

sort_reg <= sort_reg(M to sort_reg'high) & sort_reg(0 to M-1);

请注意，如果您想转换一个信号（而不是将其分配给不同的信号），您应该按照Martin 所述的流程进行。