为什么 VBA 函数会为集合提供编译错误，但不会为字符串提供编译错误

Question

我正在尝试将集合传递给 VBA 函数，但出现编译错误，我似乎无法修复。

这是给出错误的简化示例。

Sub test()
    Dim fooString As String
    Dim fooCollection As collection
    Set fooCollection = New collection
    useString (fooString)
    useCollection (fooCollection)
End Sub

Public Function useString(foo As String)
    MsgBox ("here")
End Function

Public Function useCollection(foo As collection)
    MsgBox ("here")
End Function

我没有看到我正在做的事情与示例中所示的不同，例如此处显示的示例：How do I sort a collection?

这是我得到的错误（编译错误：参数不是可选的）：

Answer 1

由于隐含的“有用”默认成员，您会收到此对话框。在对象浏览器中导航到类窗格中的集合，在成员中，您将看到 Item 是默认成员，由蓝绿色图标指定。

这是另一个例子。在运行代码之前问问自己它将打印什么并大声说出来。

Public Sub DontWrapIt()
    Dim foo As Range
    Set foo = Sheet1.Range("A1")
    GiveMeARange foo
    GiveMeARange (foo)
End Sub

Private Sub GiveMeARange(ByVal param As Variant)
    Debug.Print TypeName(param)
End Sub

用括号包装对象会导致对其进行评估，这会导致隐式调用“有用的”默认成员...这需要未提供的Index 参数 - 因此，“参数不是可选的”。

Answer 2

我不知道为什么会给出那个特定的错误（而不是更多信息的错误），但是当你调用一个 sub 或一个函数作为 sub （不使用返回值）时，你不应该有括号论据。以下作品：

Sub test()
    Dim fooString As String
    Dim fooCollection As collection
    Set fooCollection = New collection
    useString fooString
    useCollection fooCollection
End Sub

Public Function useString(foo As String)
    MsgBox "here"
End Function

Public Function useCollection(foo As collection)
    MsgBox "here"
End Function

但是——如果你的函数没有真正返回任何东西，也许你可以将它们定义为 subs 开始。在 VBA 中，在像 C 这样的语言中创建一个 void 函数确实没有任何意义。

Answer 3

只是调用另一个子的问题..

如果它没有任何参数，你可以只用名字来调用它：

useCollection 或 Call useCollection

如果它确实有参数，那么你要么不带括号调用它，要么使用Call：

useCollection parameter 或 Call useCollection(parameter)

Sub test()
    Dim fooString As String
    Dim fooCollection As Collection
    Set fooCollection = New Collection
    useString (fooString)

    fooCollection.Add "test message", "test"
    useCollection fooCollection
    Call useCollection(fooCollection)
End Sub

Public Function useString(foo As String)
    MsgBox ("here")
End Function

Public Function useCollection(foo As Collection)
    MsgBox foo(1)
End Function

查看更多关于Call statement的信息：

调用过程时不需要使用 Call 关键字。但是，如果您使用 Call 关键字调用需要参数的过程，则 argumentlist 必须用括号括起来。如果省略 Call 关键字，则还必须省略 argumentlist 周围的括号。如果您使用 Call 语法来调用任何内部或用户定义的函数，则该函数的返回值将被丢弃

Answer 4

这行得通：

Sub test()
    Dim fooString As String
    Dim fooCollection As VBA.collection
    Set fooCollection = New VBA.collection
    fooCollection.Add "bar", "bar"
    useString (fooString)
    useCollection fooCollection
End Sub

Public Function useString(foo As String)
    MsgBox ("useString")
End Function

Public Function useCollection(ByRef foo As VBA.collection)
    MsgBox ("useCollection")
End Function