对（键，字符串）对的动态集进行排序VB6答案

【问题标题】：Sort dynamic set of (key, string) pairs VB6对（键，字符串）对的动态集进行排序VB6
【发布时间】：2018-09-20 10:51:24
【问题描述】：

谁能告诉我使用VB6对由键设置的动态（键，字符串）进行排序的最佳方法是什么。我曾尝试使用 VBA.collections 和 2D 数组。但他们似乎有一个很大的解决方法来进行排序。我还尝试了MSComctlLib.ListView 中提到的stackoverflow question.

Dim lvSelectedStyles As MSComctlLib.ListView
Dim listItem As MSComctlLib.listItem
'Some code here
lvSelectedStyles.ListItems.Add Key:=CStr(lngCount) Text:=objParagraph.Key

但是添加此项目会给出错误消息“未设置对象或块变量”。如果我能完成这个，我可以按列对列表视图进行排序并继续前进。

谁能告诉我一个克服这个问题的方法，或者如果你有任何其他方法可以做到这一点，请告诉我。

谢谢。

【问题讨论】：

您是否使用Set 来新建lvSelectedStyles？
我试过了，但是设置 lvSelectedStyles = New ... vb 在这里没有给出建议 MSComctlLib.ListView。我被卡住了。
似乎无法使用 New 创建 ListView，因此我看到了几个选项：首先，您可以将 ListView 拖放到隐藏表单上。其次，您可以使用 Dictionary 并编写一些自定义代码对其进行排序。本网站和其他网站上有示例。
@BrianMStafford 我在我的表单中创建了一个列表视图（不可见）并使用 listview.sort ，我现在可以按照我的意愿进行排序。谢谢。
可以使用 .NET 框架集合创建一个 VB (.NET) 或 C# 类，并从 VB6 访问该类。但这可能不是最方便/直接的方法。

标签： vb6

【解决方案1】：

尝试使用 Recordset 对象进行这样的排序

Option Explicit

Private Function pvSortImpl(vData As Variant, _
            ByVal lKeyType As Long, _
            ByVal lKeySize As Long, _
            ByVal lValueType As Long, _
            ByVal lValueSize As Long) As Variant
    Const adFldIsNullable As Long = 32
    Dim rs              As Object
    Dim vElem           As Variant
    Dim vFields         As Variant
    Dim vRetVal         As Variant
    Dim lIdx            As Long
    Dim oFldKey         As Object
    Dim oFldValue       As Object

    Set rs = CreateObject("ADODB.Recordset")
    rs.Fields.Append "Key", lKeyType, lKeySize, adFldIsNullable
    rs.Fields.Append "Value", lValueType, lValueSize, adFldIsNullable
    rs.Open
    vFields = Array(0, 1)
    For Each vElem In vData
        rs.AddNew vFields, vElem
    Next
    If rs.RecordCount = 0 Then
        vRetVal = Array()
    Else
        rs.Sort = "Key"
        ReDim vRetVal(0 To rs.RecordCount - 1) As Variant
        Set oFldKey = rs.Fields("Key")
        Set oFldValue = rs.Fields("Value")
        rs.MoveFirst
        Do While Not rs.EOF
            vRetVal(lIdx) = Array(oFldKey.Value, oFldValue.Value)
            lIdx = lIdx + 1
            rs.MoveNext
        Loop
    End If
    pvSortImpl = vRetVal
End Function

Public Function SortNumeric(vData As Variant) As Variant
    Const adDouble      As Long = 5
    Const adVarWChar    As Long = 202

    SortNumeric = pvSortImpl(vData, adDouble, 0, adVarWChar, 1000)
End Function

Public Function SortStrings(vData As Variant) As Variant
    Const adVarWChar    As Long = 202

    SortStrings = pvSortImpl(vData, adVarWChar, 202, adVarWChar, 1000)
End Function

Private Sub Form_Load()
    Dim vResult         As Variant

    vResult = SortStrings(Array(Array("bbb", "test"), Array("aaa", Now)))
    Debug.Print Join(vResult(0), "=>")
    Debug.Print Join(vResult(1), "=>")
    vResult = SortNumeric(Array(Array("33", "test"), Array("2.2", Now), Array("22", "Proba")))
    Debug.Print Join(vResult(0), "=>")
    Debug.Print Join(vResult(1), "=>")
    Debug.Print Join(vResult(2), "=>")
End Sub

在即时窗口中打印

aaa=>9/21/2018 11:50:19 AM
bbb=>test
2.2=>9/21/2018 11:50:19 AM
22=>Proba
33=>test

【讨论】：