Windows 批处理文件中的 For 循环：错误：“命令的语法不正确”

Question

这是我在此线程中提出的问题的后续行动： Extracting string after last instance of delimiter in a Batch file

我正在编写一个批处理文件，该文件采用未知数量的字符串作为参数，这些字符串表示来自 java 程序（调用 .bat）的目录。这些目录保存在一个名为“dirs”的“数组”中。

for /F "tokens=2 delims==" %%z in ('set dirs[') do (
    set "parm=%~1"
    for %%a in (%parm:\= %) do set folder=%%a
    echo %folder%
    shift
)

“dirs”数组将保留实际目录而不以任何方式更改它，最终我将使用它与 xcopy 作为要从中复制的目录。 Parm 将实际参数放入批处理文件并对其进行操作以提取目录的最后一部分。名为“文件夹”的变量存储此目录名称并将其打印到命令行。但是，当我运行程序时，我经常收到一条错误消息，提示“命令的语法不正确”。我尝试缩小问题的确切位置，并且肯定在上述循环内。为了使外循环工作，是否必须以某种方式操作 %%z ？当我用一个简单的“echo %%z”替换它的内容时，循环会起作用，所以这让我想知道这是否是问题所在。

编辑：这是更新后的循环，包括 xcopy 行：

for /F "tokens=2 delims==" %%z in ('set dirs[') do (
set "param=%~1"
set param=!param:\= !
for %%a in (!param!) do set lastDir=%%a
    echo !lastDir!
XCOPY %%z\*.* !outdrive!:\!dir!\!lastDir! /C /S /D /Y /I
shift
)

如果您需要知道，“outdrive”是外部硬盘，“dir”是程序前面创建的备份目录，lastDir 应该是不言自明的。它是文件夹名称，即“图片”或“文档”

最终编辑：

感谢所有回复的人。我因为之前没有看到答案而自责，但我已经找到了一些可以按预期工作的代码。这是当前所在的循环，运行正常：

for /F "tokens=2 delims==" %%z in ('set dirs[') do (
    set param=%%z
    set param=!param:\= !
    for %%a in (!param!) do set lastDir=%%a
    XCOPY %%z\*.* !outdrive!:\!dir!\!lastDir! /C /S /D /Y /I
)

我没有使用传入批处理文件的参数，而是直接从“dirs”数组工作。然后，我将一个不同的变量设置为指定的目录字符串，并对该变量进行操作，而不是存储在数组中的字符串。

Answer 1

如果您需要在循环中使用变量，请使用延迟扩展和 !variables! 的更改语法。

shift 命令对循环变量没有任何作用。

Answer 2

根据更新的信息，这应该会显示您需要的命令，并且此代码 sn-p 中不需要延迟扩展。

@echo off
set outdrive=E
set dir=backup

set dirs[1]=c:\folders1
set dirs[2]=c:\folders2
set dirs[3]=c:\folders3
set dirs[4]=c:\folders4

for /F "tokens=2 delims==" %%z in ('set dirs[') do (
echo XCOPY "%%z\*.*" "%outdrive%:\%dir%\%%~nxz\" /C /S /D /Y /I
)
pause