Netlogo 导出/Tableau 问题

Question

目前我正在尝试将我的数据从 Netlogo 导出到 CSV 文件，然后使用以下代码将其加载到 Tableau 中..

to write-result-to-file
  ; if nothing to write then  stop
  if empty? Result-File [stop]
  ; Open file
  file-open Result-File

  ; Write into the file
  file-print (word Days-passed "," num-susceptible "," num-infected "," num-recovered)
  ; Close file
  file-close
end

遇到麻烦的地方是，当我将数据加载到画面中时，它没有正确获取度量/维度。 Netlogo 中是否有一种方法可以在将我的每一行/列导出到 CSV 文件之前指定它们的标题？

Answer 1

这个问题是在 NetLogo 用户上提出并回答的。下面复制了 James Steiner 的答案，并更正了代码中的一些拼写错误。真的很优雅。

---

您可以在设置过程中将标题打印到结果文件中！

您可能想要创建一个子程序来处理所有对文件的写入，因此您不必重复代码：

to write-csv [ #filename #items ]
  ;; #items is a list of the data (or headers!) to write.
  if is-list? #items and not empty? #items
  [ file-open #filename
  ;; quote non-numeric items
  set #items map quote #items
  ;; print the items
  ;; if only one item, print it.
  ifelse length #items = 1 [ file-print first #items ]
  [file-print reduce [ (word ?1 "," ?2) ] #items]
  ;; close-up
  file-close
  ]
end

to-report quote [ #thing ]
  ifelse is-number? #thing
  [ report #thing ]
  [ report (word "\"" #thing "\"") ]
end

---

你可以用

来调用它

write-csv "myfilename.csv" ["label1" "label2" "label3"]

在设置例程中写入列标题，然后

write-csv "myfilename.csv" [10.0 "sometext" 20.3]

写入一行数据 - 在本例中是一个数字、一个字符串和另一个数字。