VBA Excel：将条件格式应用于空白单元格

Question

我正在尝试编写一个子过程，它将某些条件格式应用于 Excel 中的一系列单元格。 我有点卡住了，所以我使用了宏记录器。但是，我无法弄清楚它为什么要应用下面的公式，而当我手动运行代码时它会失败。

• 我要做的是对范围内的空白单元格应用条件格式。
• 我想将单元格颜色设为灰色
• 范围是一个表，该表称为“Table1”。
• 我需要在 sub 中执行此操作，因为表会动态刷新。

以下是录制的宏，它不起作用，而是将格式应用于错误的单元格。 任何纠正它的帮助将不胜感激

谢谢

Sub MacroTest()

    Range("Table1").Select
    'The below formula is wrong but I can't figure out what it should be
    Selection.FormatConditions.Add Type:=xlExpression, Formula1:="=LEN(TRIM(D15))=0"
    With Selection.FormatConditions(1).Interior
        .PatternColorIndex = xlAutomatic
        .ThemeColor = xlThemeColorAccent2
        .TintAndShade = 0.399945066682943
    End With
    Selection.FormatConditions(1).StopIfTrue = False

End Sub

Answer 1

改变

Selection.FormatConditions.Add Type:=xlExpression, Formula1:="=LEN(TRIM(D15))=0"

到

Selection.FormatConditions.Add Type:=xlExpression, Formula1:= _
"=LEN(TRIM(C" & Range("Table1").Row & "))=0"

所以你的代码可以写成

Sub Sample()
    With ThisWorkbook.Sheets("Sheet1").Range("Table1")
        .FormatConditions.Add Type:=xlExpression, Formula1:= _
        "=LEN(TRIM(C" & .Row & "))=0"
        .FormatConditions(.FormatConditions.Count).SetFirstPriority
        With .FormatConditions(1).Interior
            .PatternColorIndex = xlAutomatic
            .ThemeColor = xlThemeColorDark2
            .TintAndShade = -9.99481185338908E-02
        End With
    End With
End Sub

Answer 2

这是我的看法，即使 Sid 已经有了很好的答案。我重新创建了一个名为 test 的表，并将其定位在 A1。我对您的代码进行了少量编辑，对我来说效果很好。

Sub Test()
Dim v As Range
Set v = Range("test")
v.ClearFormats
v.FormatConditions.Add Type:=xlExpression, Formula1:="=LEN(TRIM(A1))=0"
With v.FormatConditions(1).Interior
        .PatternColorIndex = xlAutomatic
        .ThemeColor = xlThemeColorAccent2
        .TintAndShade = 0.399945066682943
End With
v.FormatConditions(1).StopIfTrue = False
End Sub

不过，请注意，在公式中使用 A2 会产生不灵活的结果，尤其是与 Sid 在上面的代码中使用的相比。

希望它有所帮助（或至少提供一些见解）！

第二次：

这件事从前几天就一直困扰着我，所以我再试一次。显然，基于这个Microsoft Support nugget，CF 似乎存在问题。存在两种解决方法：使用绝对引用或在应用 CF 之前先选择单元格。

我玩了一会儿，在绝对参考下得到了很多错误的结果。然而，一种简单的方法是有效的。我们选择Table1的第一个单元格并给它CF，然后我们使用书中最简单的方法：格式刷！我们还将.ClearFormats 替换为.FormatConditions.Delete。

以下是使用上述方法的代码变体：

Sub Test()
Dim Table1 As Range: Set Table1 = ThisWorkbook.Sheets("Sheet1").Range("Table1")
    Start = Timer()
    Application.ScreenUpdating = False
    Table1.FormatConditions.Delete
    With Table1.Cells(2, 1)
    'With Range("B7")
        .Select
        .FormatConditions.Add Type:=xlExpression, Formula1:= _
        "=LEN(TRIM(B7))=0"
        .FormatConditions(.FormatConditions.Count).SetFirstPriority
        With .FormatConditions(1).Interior
                .PatternColorIndex = xlAutomatic
                .ThemeColor = xlThemeColorAccent2
                .TintAndShade = 0.399945066682943
        End With
        .FormatConditions(1).StopIfTrue = False
        .Copy
    End With
    Table1.PasteSpecial xlPasteFormats 'or the next one
    'Range("B7:AO99").PasteSpecial xlPasteFormats
    Application.CutCopyMode = False
    Application.ScreenUpdating = True
    Debug.Print Timer() - Start
End Sub

这是结果预览。

执行时间（以秒为单位）为：

• 4.296875E-02
• 4.492188E-02
• 5.273438E-02
• 5.859375E-02
• 0.0625

这些比我之前的尝试要快得多，我之前循环遍历所有单元并为每个单元添加 CF。

希望对您有所帮助！

Answer 3

经过一番搜索，我发现了一个不使用函数 LEN 并且需要使用 xlBlanksCondition 指定范围的选项。 如果宏记录器也可以使用 xlBlanksCondition 解决方案，我不明白为什么它会提出 LEN 解决方案。

来源：MSDN Microsoft

我首先选择一个范围，然后应用此代码：

With Selection.FormatConditions.Add(Type:=xlBlanksCondition)
    .StopIfTrue = False
    .Interior.PatternColorIndex = xlAutomatic
    .Interior.Color = RGB(226, 80, 80)
    .Interior.ThemeColor = xlThemeColorAccent2
    .Interior.TintAndShade = 0.39
    .Font.Color = vbBlack
    .Font.TintAndShade = 0
    .Borders.LineStyle = xlContinuous
    .Borders.TintAndShade = 0
    .Borders.Weight = xlThin
    .Borders.Color = RGB(255, 0, 0)
    .StopIfTrue = False
End With