在 VBA 中使用条件格式

Question

我正在使用循环在“D 列”的“每 4 行”中放置一个条件格式。但是，我无法正确获取代码。

我发生了两件不同的事情。首先，我在电子表格中显示了公式，公式周围有“”，条件格式不起作用。所以现在我正在尝试使用以下代码重写它，它告诉我编译错误预期语句结束。

任何有关如何使D(i-1)>sum(D(i):D(i+2) 阴影单元格红色工作的条件格式的帮助表示赞赏。

这是我试图遮蔽的 For/Next 循环的中间部分。

    Range("D" & (i - 1)).Select
        Selection.FormatConditions.Add Type:=xlExpression, Formula1:="D" & (i-1) & "> Sum(D" & i & "D" & (i + 2)")"

        Selection.FormatConditions(Selection.FormatConditions.Count).SetFirstPriority

        With Selection.FormatConditions(1).Interior
            .PatternColorIndex = xlAutomatic
            .Color = 255
            .TintAndShade = 0
        End With
        Selection.FormatConditions(1).StopIfTrue = False

        i = i + 4

Answer 1

这对我有用：

Sub Tester()

    Dim i As Long, fc As FormatCondition

    For i = 2 To 10 Step 4

        Set fc = ActiveSheet.Range("D" & (i - 1)).FormatConditions. _
                       Add(Type:=xlExpression, _
                       Formula1:="=D" & (i - 1) & "> Sum(D" & i & ":D" & (i + 2) & ")")

        fc.SetFirstPriority

        With fc.Interior
            .PatternColorIndex = xlAutomatic
            .Color = 255
            .TintAndShade = 0
        End With

        fc.StopIfTrue = False

    Next i

End Sub

Answer 2

是否需要在 VBA 中执行此操作？我之所以问，是因为通过常规条件格式，您还可以轻松地将其应用于每 4 行。

为此，您只需要在条件格式中使用如下公式即可：

=AND(MOD(ROW($D5),4)=0, $D5 > SUM($D$2:$D4))

MOD 函数将行号除以 4 并检查余数是否为 4。

这不是你所要求的，但它可能会解决你的情况......