如何用 XSLT 替换 XML 中的部分行？

Question

我有以下 XML 文件：

<?xml version="1.0" encoding="UTF-8"?>
<mets:mets xmlns:mets="http://www.loc.gov/METS/">
 <mets:fileSec>
    <mets:fileGrp ID="rep1" ADMID="rep1-amd">
      <mets:file ID="fid1-1" ADMID="fid1-1-amd">
        <mets:FLocat xmlns:xlin="http://www.w3.org/1999/xlink" LOCTYPE="URL" xlin:href="/exlibris1/transfer/lza-tib/submission.tib/ingest/GBV631313192/content/streams/MASTER/Prandtl_4.pdf"/>

      </mets:file>
    </mets:fileGrp>
    <mets:fileGrp ID="rep2" ADMID="rep2-amd">
      <mets:file ID="fid1-2" ADMID="fid1-2-amd">
        <mets:FLocat xmlns:xlin="http://www.w3.org/1999/xlink" LOCTYPE="URL" xlin:href="/exlibris1/transfer/lza-tib/submission.tib/ingest/GBV631313192/content/streams/DERIVATIVE_COPY/631313192.pdf"/>
      </mets:file>
    </mets:fileGrp>
  </mets:fileSec>
</mets:mets> 

对于每个 mets:FLocat 我想做以下更改：

现在： <mets:FLocat xmlns:xlin="http://www.w3.org/1999/xlink" LOCTYPE="URL" xlin:href="/exlibris1/transfer/lza-tib/submission.tib/ingest/GBV631313192/content/streams/MASTER/Prandtl_4.pdf"/>

必须是：<mets:FLocat LOCTYPE="URL" xlin:href="file://MASTER/Prandtl_4.pdf" xmlns:xlin="http://www.w3.org/1999/xlink"/>

所以我们删除/exlibris1/transfer/lza-tib/submission.tib/ingest/GBV631313192/content/streams，而不是添加file://

这是我的 XSLT：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"
xmlns:dc="http://purl.org/dc/elements/1.1/"
xmlns:dcterms="http://purl.org/dc/terms/">

<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes" />

    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>


 <xsl:for-each select="/mets:mets/mets:filesec/mets:fileGrp/mets:file/mets:Flocat"> 
    <xsl:value-of select="xlin:href"/>
</xsl:for-each> 
    </xsl:template>

</xsl:stylesheet>

我对 XSLT 非常陌生，我不知道如何引用我必须更改的行。也许有一些想法？

Answer 1

考虑使用 XSLT 3（由 Saxon 9.8 或 Altova XMLSpy 2017 或 2018 支持），然后就很简单了

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    xmlns:mets="http://www.loc.gov/METS/"
    xmlns:xlin="http://www.w3.org/1999/xlink"
    exclude-result-prefixes="#all"
    version="3.0">

  <xsl:mode on-no-match="shallow-copy"/>

  <xsl:template match="mets:FLocat/@xlin:href">
      <xsl:attribute name="{name()}" select="'file://' || replace(., '^/exlibris1/transfer/lza-tib/submission.tib/ingest/GBV631313192/content/streams', '')"/>
  </xsl:template>

</xsl:stylesheet>

http://xsltfiddle.liberty-development.net/nbUY4kn

对于 XSLT 2，您需要将身份转换拼写为

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    xmlns:mets="http://www.loc.gov/METS/"
    xmlns:xlin="http://www.w3.org/1999/xlink"
    exclude-result-prefixes="#all"
    version="2.0">

  <xsl:template match="@* | node()">
      <xsl:copy>
          <xsl:apply-templates select="@* | node()"/>
      </xsl:copy>
  </xsl:template>

  <xsl:template match="mets:FLocat/@xlin:href">
      <xsl:attribute name="{name()}" select="concat('file://', replace(., '^/exlibris1/transfer/lza-tib/submission.tib/ingest/GBV631313192/content/streams', ''))"/>
  </xsl:template>

</xsl:stylesheet>

http://xsltfiddle.liberty-development.net/nbUY4kn/2

使用 XSLT 1 没有一般的字符串替换，但是您可以在某个字符串之后使用属性值的结尾

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    xmlns:mets="http://www.loc.gov/METS/"
    xmlns:xlin="http://www.w3.org/1999/xlink"
    exclude-result-prefixes="xs mets xlin"
    version="1.0">

  <xsl:template match="@* | node()">
      <xsl:copy>
          <xsl:apply-templates select="@* | node()"/>
      </xsl:copy>
  </xsl:template>

  <xsl:template match="mets:FLocat/@xlin:href">
      <xsl:attribute name="{name()}">
          <xsl:value-of select="concat('file://', substring-after(., '/exlibris1/transfer/lza-tib/submission.tib/ingest/GBV631313192/content/streams'))"/>
      </xsl:attribute>
  </xsl:template>

</xsl:stylesheet>

http://xsltfiddle.liberty-development.net/nbUY4kn/3