Vlookup 的总和答案

【问题标题】：Total Sum With VlookupVlookup 的总和
【发布时间】：2021-09-22 14:47:36
【问题描述】：

我有两个包含名称和时间的电子表格。一个是特定的会话时间，在第二张纸上，我想根据第一张纸上的每个实例总结总时间。

Sheet 1: Session Time
Name   |   Time 
David        5
Mike         2
Daniel       3
David        2
Daniel       8


Sheet 2: Total Time (The one for which I need a forumula)

Name   |  Total Time
David        7
Mike         2
Daniel       11

我尝试了 countif 和 vlookup，但我无法让它匹配表 1 上的多个名称实例。我还尝试了建议帖子中的这个建议公式，但它没有总结用户名的第二个实例

=ARRAYFORMULA(SUM(ifna(VLOOKUP(A2, 'Sheet 1'!A3:AA16, 5, false))))

A2 = 大卫（在第 2 页上）

Sheet 1'!A3:AA16 = A 列中的名称列表，一直到 AA 是一系列带有数值的列

5 = 我想要返回每个 David 实例的总和的列号（在本例中为 2，总共 7）

False = 未排序

任何帮助都非常重要！

【问题讨论】：

见webapps.stackexchange.com/questions/25798/…

标签： google-sheets google-sheets-formula

【解决方案1】：

您可以在Sheet2!B1 中使用此公式：

={"Total Time";arrayformula(if(A2:A<>"",sumif(Sheet1!A1:A,A2:A,Sheet1!B1:B),""))}

或者干脆在Sheet2!B2中使用=arrayformula(if(A2:A<>"",sumif(Sheet1!A1:A,A2:A,Sheet1!B1:B),""))

使用SUMIF()获取基于特定条件的范围总和
基本上，如果Sheet1!A1:A 与arrayformula A2:A 中正在检查的当前单元格匹配，则得到Sheet1!B1:B 的总和

输出：

【讨论】：

如果您遇到了一些问题，请告诉我。我只是根据您提供的样本中的样本表数据。我不明白您为什么从之前的公式中使用Sheet 1'!A3:AA16。如果您无法使建议的解决方案在您身边发挥作用，您可能希望共享一个样本表。 Share a test sheet
实际上，我所需要的只是一个简单的“sumif”，我只是不熟悉这个命令，并试图将逻辑表达式分层到一个常规的 if 语句中。不过还是谢谢大家的建议。

【解决方案2】：

这可以通过一个简单的查询来完成，例如，

=QUERY('Session Time'!A:B, "Select A, SUM(B) WHERE A Is Not Null GROUP BY A LABEL SUM(B) 'Total Time'")

【讨论】：