如何从网站执行 vbscript答案

【问题标题】：how to execute vbscript from website如何从网站执行 vbscript
【发布时间】：2012-01-12 19:24:16
【问题描述】：

我有一个 VBScript 文件。当它在计算机上时，它工作正常。我想把它放在一个 php 站点上，以便通过单击按钮来执行它。但我没有成功。它实际上获取计算机信息。希望它能在用户机器上运行。任何想法将不胜感激。如果或是否有人知道如何使用 jscript 进行操作

代码如下：

strComputer = "."

Set objWMIService = GetObject("winmgmts:" _
    & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")

Set colSettings = objWMIService.ExecQuery _
    ("Select * from Win32_OperatingSystem")

For Each objOperatingSystem in colSettings 
    Wscript.Echo "OS Name: " & objOperatingSystem.Caption
    Wscript.Echo "Version: " & objOperatingSystem.Version  
    Wscript.Echo "Available Physical Memory: " & _
        objOperatingSystem.FreePhysicalMemory
Next

Set colSettings = objWMIService.ExecQuery _
    ("Select * from Win32_ComputerSystem")
For Each objComputer in colSettings 
        Wscript.Echo "Total Physical Memory: " & _
        objComputer.TotalPhysicalMemory
Next

Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\CIMV2")

Set colSettings= objWMIService.ExecQuery _
    ("SELECT * FROM Win32_DiskDrive")
For Each objItem In colSettings
      WScript.Echo "Disk Size: " & objItem.Size 
   Next

Dim WSHShell 
Dim objAdr 
On error resume next 
Set WSHShell = WScript.CreateObject("WScript.Shell") 
test = wshshell.RegRead("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Microsoft SQL Server\Instance Names") 
If err.number > 0 Then 
msgbox "SQL Server not found" 
else msgbox "SQL Server found" 
end if

【问题讨论】：

您想在客户端机器上运行这个 VBScript 来获取客户信息吗？
也许您不记得 ILOVEYOU 蠕虫？
@rkosegi 我想要的是一种让用户访问网站并检查他们的计算机是否可以运行我们的软件的方法，但我只是在尝试不同的东西，所以如果你有另一个想法，如果你可以分享因为我一无所知
如果您想访问客户端 PC 上安装的操作系统版本等信息，最好的方法是使用 ActiveX 或 Java。我希望您可以在英特尔页面上使用类似 java 小程序的东西来检查安装的版本drivers.Using VBScript 它只适用于 IE，但不能访问 WMI 或其他特权代码（可能在“受信任的站点”中）

标签： php vbscript system jscript

【解决方案1】：

好吧，让我们假设我们生活在一个你想要的世界里：

世界上的每个网络服务器都可以将代码转储到客户端计算机上并执行它
您的机器将愉快地执行网络服务器想要的任何操作
在用户不知情的情况下静默进行。
神奇地将世界上的每台机器变成一台 Windows PC，以便执行此 VB 脚本代码
讽刺检测器在网络上变得司空见惯，前面的 4 点将照此显示。

网络浏览器被锁定，以防止您的窥探代码尝试执行的滥用行为类型，因为您的代码尝试从计算机检索的内容与您无关。

【讨论】：

我的朋友..那个世界被称为.. 90年代后期。
好吧，我想要的是一种让用户访问网站并检查他们的计算机是否可以运行我们的软件的方法，但我只是在尝试不同的东西，所以如果你有其他想法，如果你可以分享因为我一无所知@MikeChristensen
有执行此类操作的 activex 控件、java 小程序等...就个人而言，如果一个站点开始请求在我的机器上运行任意 snoop 内容的权限，我再也不会回到那个站点.
它不是用来窥探的，只是试着按照我老板的要求去做，请原谅我对这些东西很陌生
网站没有任何业务来确定我的硬件/软件参数。一个可以做到这一点的网站基本上也可以做任何其他事情。

【解决方案2】：

如果你（尤其是 chloe 的老板）同意，那

网站不应监视客户的计算机
用户有权在他即将安装的软件的系统要求方面获得一点帮助
此类帮助不应涉及降低安全设置

你的选择是

列出要求并详细说明如何确定它们
windows：向用户提供（下载）生成/显示适当报告的 HTA (HTML Application) 的源
unix/linux：向用户提供（下载）脚本源（选择至少两种流行语言），生成/显示适当的报告
鉴于您无论如何都会编写一个检查要求的安装程序，您可以将这些检查捆绑到一个独立的“确保要求”应用程序中

如果您认为 HTA 是合适的，请说出来，我会添加到这个答案中。

让您开始：

简约的 sysreq.hta：

<html>
    <head>
      <title>System Requirements For XXX</title>
      <hta:application
         id="sysreq"
      ></hta>
      <script type="text/vbscript" src="sysreq.vbs"></script>
      <script type="text/jscript" src="sysreq.js"></script>
    </head>
    <body onload="onload">
      <table id="tblSysReq" border="1" summary="KeepTidyHappy">
       <tr>
        <td id="tdOS">
        </td>
       </tr>
       <tr>
        <td id="tdMSSQL">
        </td>
       </tr>
      </table>
    </body>
</html>

对于生产版本，您应该使用 HTML 编辑器/ide 编写一个漂亮的页面，然后插入 hta 元素。有一个相当过时的wizard 可以帮助您将 HTA 特定（交互式）元素/代码放入您的 HTML。一些 MS 安装 CD/DVD/ISO 包含一个 setup.hta，您可以使用它来获得更多灵感；一些谷歌搜索会将您指向 .hta 应用程序，例如 System Documenter Wizard。如果没有仔细的单步测试，这些来源都不可信；例如：我从 the official docs 开始我的 .hta，直到我删除了讨厌的 <meta http-equiv="x-ua-compatible" content="ie=9"> 之后才让它在 Windows 7 上运行。

虽然您可能会将您的脚本内嵌到 .hta 中，但为了开发，最好通过 script 标签的 src 属性包含代码。在 sysreq.vbs 中：

Sub onload()
    strComputer = "."
    Set objWMIService = GetObject("winmgmts:" _
        & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
    Set colSettings = objWMIService.ExecQuery("Select * from Win32_OperatingSystem")
    For Each objOperatingSystem in colSettings
        ' Wscript.Echo "OS Name: " & objOperatingSystem.Caption
        document.getElementById("tdOS").innerText = "OS Name: " & objOperatingSystem.Caption
    Next
    If False Then
       Dim WSHShell : Set WSHShell = CreateObject("WScript.Shell")
      On error resume next
       ' test = wshshell.RegRead("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Microsoft SQL Server\Instance Names")
       test = wshshell.RegRead("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Microsoft SQL Server\Instance Names\SQL\SQLEXPRESS")
       If 0 <> Err.Number Then
          ' msgbox "SQL Server not found"
          MsgBox Err.Description
          test = "SQL Server <b>not</b> found"
       Else
          ' msgbox "SQL Server found"
          test = "<i>SQL Server found</i>"
       End If
       document.body.all("tdMSSQL").innerHTML = test
    Else
       JsHelper
    End If
End Sub

我尝试按照您发布的代码进行操作；必要的更改是通过使用document.getElementById() 或document.body.all() 将WScript.Echo 输出“写入”到HTML 元素的innerText/HTML 来替换。

要获得用于收集信息的想法/示例代码，请查看Scriptomatic 之类的工具。正如你提到的 JScript，我扔进了 sysreq.js：

function JsHelper() {
    var WSHShell = new ActiveXObject("WScript.Shell")
    try {
      var test = WSHShell.RegRead("HKEY_LOCAL_MACHINE\\SOFTWARE\\Microsoft\\Microsoft SQL Server\\Instance Names\\SQL\\SQLEXPRESS");
      document.all.tdMSSQL.innerHTML = "<i>SQL Server found</i>";
    }
    catch(e) {
      alert(e);
      document.all.tdMSSQL.innerHTML = "SQL Server <b>not</b> found";
    }
}

让您比较处理相同问题的 JScript 和 VBScript 代码。

这是值得的 - 我使用非特权用户帐户在 Windows XP 和 7 上对此进行了测试；我希望您的里程不会有所不同。

WRT chloe 的问题“是否可以将两种不同的脚本语言放在同一个 hta 中？”：在 .HTA（和 .WSF 或 .WSC）中，您可以混合所有（已安装的）ActiveScript 语言（VBScript、JScript、Perlscript、 Pythonscript, Rubyscript, ...) 通过使用内联或通过 src 属性的脚本标签。这非常适合学习，但通常不适合生产代码。

【讨论】：

我阅读了 html 应用程序链接，听起来很合适，在此先感谢您发布答案。
是否可以将两种不同的脚本语言放在同一个 hta 中？
在代码中添加了更多内容，其中包含您的更改，如果您不介意查看它，那么您可以告诉我，我会发布的，我想知道我是否使用src 标签，不包含 Sub 代码并将其保存为 hta 是否仍会引用外部脚本？

【解决方案3】：

您可以像外部 js 文件一样包含外部 vbscript 文件，但它只能在具有特殊权限的 Windows 环境中的 IE 中运行。

您可以使用 ActiveXObject 从客户端计算机运行可执行文件，并且该可执行文件需要安装在客户端计算机上，并具有适当的权限，浏览器才能执行它。

使用 ActiveXObject 的 javascript 示例：

var shellActiveXObject = new ActiveXObject("WScript.Shell");
shellActiveXObject.CurrentDirectory = currentFolder;
shellActiveXObject.Run(executableFullPath, 1, false);
shellActiveXObject = null;

【讨论】：

你能给我更多的信息吗
我很久以前只在asp.net做过..这个例子可能会对你有所帮助：forums.asp.net/t/1246508.aspx/…