将 Excel 列转换为 csv 数据

Question

我希望 Excel 工作表的每一列都变成一个 CSV 文件，仅以该列作为其唯一的一行。

例如，从随附的 Excel 屏幕截图中，我的输出应该是两个 csv 文件（因为有 2 列），每个文件都有一行。
也就是说，第一个 csv 变量将来自 1-9，而第二个将来自 11-19。

Answer 1

你很幸运，我刚刚花了一周的时间来解决一个类似的问题。我根据您的问题对其进行了调整。

享受吧！

   Private Sub SplitColumnsInCSV()

    Dim wb As Workbook
    Dim ws As Worksheet
    Dim TableToSplit As ListObject
    Dim WorkbookPath As String
    Dim CSVLocation As String
    Dim FilePath As String
    Dim Folder As String
    Dim i, j, TableColumnCount As Integer
    Dim TempRangeToSplit As Range
   
    Set wb = ActiveWorkbook

    'Real name of your worksheet where your table is located
    Set ws = wb.Worksheets("Feuil1")

    'Real name of your table in your worksheet
    Set TableToSplit = ws.ListObjects("TableToSplit")

    For i = 1 To TableToSplit.ListColumns.Count
        'adjust temp range for each columns
        Set TempRangeToSplit = TableToSplit.ListColumns(i).Range
        
        'Create à folder with your CSV  where your workbook is located
        CSVLocation = wb.Path & "\CSV\"
        Folder = Dir(CSVLocation, vbDirectory)
        If Folder = "" Then MkDir CSVLocation
    
        'name the csv file
        FilePath = wb.Path & "\CSV\" & ws.Name & TempRangeToSplit.Cells(1, 1).Value & ".csv"
        
        'this piece of code have 2 loops in case of 2 dimentionnal range
        Open FilePath For Output As #1
            For j = 1 To TempRangeToSplit.Rows.Count
                For k = 1 To TempRangeToSplit.Columns.Count
                    cellValue = TempRangeToSplit.Cells(j, k).Value
                    If k = TempRangeToSplit.Columns.Count Then
                        Write #1, cellValue
                    Else
                        Write #1, cellValue,
                    End If
                Next k
            Next j
        Close #1
    Next i
End Sub

详细说明：

• 我用要在 CSV 中提取的列填充临时范围
• 我创建一个文件夹以防它不存在
• 我创建了 csv 文件并为其命名
• 我在 csv 文件中写入一列的所有行

小心，如果你重复使用宏，新的同名文件会覆盖旧的。

Answer 2

将列导出到行

• 将范围的每一列导出到一行.csv-file。
• 调整常量部分中的值。

Option Explicit

Sub exportColumnsToCSV()
    
    Const FolderPath As String = "F:\Test\2021\66730122\"
    Const FileLeft As String = "File "
    Const csvDelimiter As String = "," ' or maybe ";"
    
    Dim rg As Range: Set rg = Range("A1").CurrentRegion
    Dim Data As Variant: Data = rg.Value
    Dim rCount As Long: rCount = UBound(Data, 1)

    Dim Result As Variant: ReDim Result(1 To rCount)
    Dim cNum As Long: cNum = FreeFile
    Dim cFile As String
    Dim c As Long, r As Long
    
    For c = 1 To UBound(Data, 2)
        For r = 1 To rCount
            Result(r) = Data(r, c)
        Next r
        cFile = FolderPath & FileLeft & c & ".csv"
        Open cFile For Output As #cNum
        Print #cNum, Join(Result, csvDelimiter)
        Close #cNum
    Next c

End Sub