是否可以从另一个 Promise 中终止 Promise 的代码块？

Question

我写了这个测试程序：

await Promise.anyof(
  Promise.allof((^5).map: {start { sleep 10; say "done $_" } }),
  Promise.in(5).then: { say 'ouch' }
);
sleep 10;

当第二个 promise 超时时，它会打印 'ouch' 并且 await 退出，但第一个 promise 的代码块仍在运行。再过五秒钟，它的五个进程结束并打印“完成”：

$ ./test1.p6
ouch
done 0
done 1
done 2
done 3
done 4

我试图终止第一个 Promise 并将其分配给一个变量，然后从第二个 Promise 调用 .break 方法，但它不起作用。

有没有办法杀死第一个 Promise 和它启动的其他五个子 Promise？

Answer 1

你必须以某种方式告诉进程它不必完成。

my $cancel = Cancellation.new;

await Promise.anyof(
  Promise.allof(
    (^5).map: {
      last if $cancel.cancelled;

      start {
        sleep 10;
        say "done $_" unless $cancel.cancelled
      }
    }
  ),
  Promise.in(5).then: {
    $cancel.cancel;
    say 'ouch'
  }
);

---

如果您想要像Promise.in() 这样可以取消的东西，让我们从looking at the existing code 开始。

method in(Promise:U: $seconds, :$scheduler = $*SCHEDULER) {
    my $p   := self.new(:$scheduler);
    my $vow := $p.vow;
    $scheduler.cue({ $vow.keep(True) }, :in($seconds));
    $p
}

注意$scheduler.cue 的结果是取消。

为了简单起见，我只是将 Promise 和 Cancellation 包装在一个类中。
（我不想重新实现每个方法）。

class Cancellable-Timer {
    has Promise      $.Promise;
    has              $!vow;
    has Cancellation $!cancel;

    method !SET-SELF ( $!promise, $!vow, $!cancel ){
        self
    }

    method in (::?CLASS:U: $seconds, :$scheduler = $*SCHEDULER) {
        my $p   := Promise.new(:$scheduler);
        my $vow := $p.vow;
        my $cancel = $scheduler.cue({ $vow.keep(True) }, :in($seconds));
        self.bless!SET-SELF($p,$vow,$cancel);
    }

    method cancel ( --> Nil ) {
        # potential concurrency problem
        if $!Promise.status == Planned {
            $!cancel.cancel;          # cancel the timer
            $!vow.break("cancelled"); # break the Promise
        }
    }

    method cancelled () {
        # Ignore any concurrency problems by using the Promise
        # as the sole source of truth.
        $!Promise.status ~~ PromiseStatus::Broken
    }
}

my $timer = Cancellable-Timer.in(1);
my $say = $timer.Promise.then: *.say;
Promise.in(0.1).then: {$timer.cancel};
await $say;

请注意，上面的课程只是一个粗略的初稿。

Answer 2

随时尝试：

$ perl6 -e '

react {
   for ^5 -> $num {
      whenever start { sleep 10 } {
         say "done $num"
      }
   }
   whenever Promise.in: 5 {
      say "ouch";
      done
   }
}

' ouch