使用 WMIC 启动程序并获取其输出

Question

我正在尝试运行一个程序并获取其 PID，以便在程序在执行期间挂起时终止该程序。我无法杀死带有程序名称的程序，因为在 PC 上运行的程序不止一个。 我遇到了论坛并得到了 wmic 使用的建议，但是我无法通过使用 wmic 调用它来获得程序的输出。

这与这篇文章中提到的问题大致相同： Remote Netstat to STDOUT with WMIC?

我按照建议尝试了这个命令来执行程序并输出：

   wmic process call create "cmd /C > C:\temp\test.txt 2>&1 netstat.exe -ano" 

使用这个命令，我可以检索程序的输出，但是程序实际上是从另一个 cmd 调用的？这违背了我最初尝试使用 wmic 的初衷。

任何人都可以告诉我是否有另一种方法来获取输出或另一种方法来从批处理中调用程序，获取它的 PID 和被调用程序的输出重定向？

Answer 1

因为你只需要PID来杀死进程，你也可以使用windowtitle：

start "UniqueWindowTitle" cmd /c "ping /t google.de >out.txt 2>&1"
timeout /t 10
taskkill /fi "WINDOWTITLE eq UniqueWindowTitle" 2>nul
type out.txt

您还可以将/min 添加为start 开关以不显示该框。

Answer 2

这是这个问题的一个例子：How to capture the PID of a process when launching it in DOS ?

@echo off
rem there is a tab in the file at the end of the line below
set tab=    
set "cmd=cmd /k ^> C:\temp\test.txt 2^>^&1 netstat.exe -ano"
set dir=%~dp0

echo Starting MyProg
set pid=notfound

for /F "usebackq tokens=1,2 delims=;=%tab% " %%i in (
    `wmic process call create "%cmd%"^, "%dir%"`
) do (
    if %%j gtr 0 (
        set "pid=%%j"
    )
)
Call :Trim "%pid%"
echo MyPID = "%pid%"
echo Hit any key to kill the process created by WMIC 
pause>nul
Taskkill /F /PID %pid%
pause & exit
::*************************************************************************************
:Trim <String>
set "vbsfile=%tmp%\%~n0.vbs"
(
    echo Wscript.echo Trim("%~1"^)
)>"%vbsfile%"
for /f "delims=" %%a in ('Cscript /nologo "%vbsfile%"') do ( set "pid=%%a" )
If Exist "%vbsfile%" Del "%vbsfile%"
exit /b
::*************************************************************************************