如何远程获取正在运行的进程列表？答案

【问题标题】：How do I get a list of running processes remotely?如何远程获取正在运行的进程列表？
【发布时间】：2011-10-30 18:54:36
【问题描述】：

如何使用 Delphi 获取其他机器（通过网络）上正在运行的进程列表？

【问题讨论】：

您已经想到或尝试过什么？
请详细说明并显示一些来源...另一台机器的操作系统是什么（Unix、Linux、OSX、Windows...）？你有什么样的网络访问（WAN / LAN ...）？中间有防火墙等吗？你试过什么？什么不工作？
查看链接获取详细信息代码Get the list of active process on a PC of my network?

标签： delphi process

【解决方案1】：

您可以使用Win32_Process WMI 类。

检查此示例

{$APPTYPE CONSOLE}
uses
  SysUtils,
  ActiveX,
  ComObj,
  Variants;


procedure  GetWin32_ProcessInfo;
const
  WbemUser            ='';//set the user name to log in
  WbemPassword        ='';//set the password
  WbemComputer        ='localhost';//set the name of the remote machine or IP address
  wbemFlagForwardOnly = $00000020;
var
  FSWbemLocator : OLEVariant;
  FWMIService   : OLEVariant;
  FWbemObjectSet: OLEVariant;
  FWbemObject   : OLEVariant;
  oEnum         : IEnumvariant;
  iValue        : LongWord;
begin;
  FSWbemLocator := CreateOleObject('WbemScripting.SWbemLocator');
  FWMIService   := FSWbemLocator.ConnectServer(WbemComputer, 'root\CIMV2', WbemUser, WbemPassword);
  FWbemObjectSet:= FWMIService.ExecQuery('SELECT * FROM Win32_Process','WQL',wbemFlagForwardOnly);
  oEnum         := IUnknown(FWbemObjectSet._NewEnum) as IEnumVariant;
  while oEnum.Next(1, FWbemObject, iValue) = 0 do
  begin
    Writeln(Format('Name         %s',[String(FWbemObject.Name)]));// String
    Writeln(Format('ProcessId    %d',[Integer(FWbemObject.ProcessId)]));// Uint32
    Writeln;
    FWbemObject:=Unassigned;
  end;
end;


begin
 try
    CoInitialize(nil);
    try
      GetWin32_ProcessInfo;
    finally
      CoUninitialize;
    end;
 except
    on E:EOleException do
        Writeln(Format('EOleException %s %x', [E.Message,E.ErrorCode]));
    on E:Exception do
        Writeln(E.Classname, ':', E.Message);
 end;
 Writeln('Press Enter to exit');
 Readln;
end.

为了在远程机器上使用 WMI，您必须设置防火墙和 DCOM 设置，请查看这些文章以获取更多信息。

【讨论】：

现在我有另一个问题......热杀进程通过网络？谢谢 :))

【解决方案2】：

请参阅 TlHelp32 单元中的 EnumProcesses 过程。

【讨论】：

EnumProcesses 不能跨机器边界工作，是吗？
没有。您需要编写一个在远程机器上运行的单独程序，然后它可以枚举该机器的本地进程并使远程应用程序可以访问该列表。
@Remy：这就是我问的原因。我想知道 Stijn 是否知道一些我不知道的关于 EnumProcesses 的事情，因为这个问题专门关于“其他机器（通过网络）”。
tss，我不应该在午夜后发帖，我完全错过了“通过网络”位...可惜这些不是开源的：technet.microsoft.com/en-us/sysinternals/bb896649