根据 power bi 中的切片器选择计算当前和上个月的值

Question

我有两个表叫

• 主表包含以下数据（图片）和
• 使用主表中的日期创建的日期表。

我想根据 日期表

中的日期切片器选择来计算两个字段/度量

• 当月收入
• 上个月的收入

示例：如果我选择第 4 个月，那么它应该将客户 A 和 B 在第 4 个月的不同收入相加为 current_month_revenue，并将 A 和 B 在第 3 个月的不同收入相加为 previous_month_revenue。

我尝试编写以下度量来计算 current_month_revenue，它工作正常，但它没有为 Previous_month_revenue 提供正确的结果。 我也得到了上个月的相同值。

'Measure Previous Month Revenue' =
IF (
    ISFILTERED ( 'Date'[Year_Month] ),
    VAR myTable =
        SUMMARIZE (
            'Main Table',
            'Main Table'[ClientName],
            'Main Table'[Mon],
            'Main Table'[Revenue]
        )
    RETURN
        CALCULATE (
            SUMX (
                myTable,
                'Main Table'[Revenue]
            ),
            FILTER (
                'Main Table',
                'Main Table'[Mon]
                    = SELECTEDVALUE ( 'Date'[Month] - 1 )
            )
        ),
    VAR myTable =
        SUMMARIZE (
            'Main Table',
            'Main Table'[Revenue],
            'Main Table'[Mon],
            'Main Table'[Revenue]
        )
    RETURN
        SUMX (
            FILTER (
                myTable,
                'Main Table'[Mon]
                    = MONTH (
                        TODAY ()
                    ) - 1
            ),
            'Main Table'[Revenue]
        )
)

期望的输出

如果选择第 4 个月

• 当前 Moth 收入 = 100 + 200 = 300
• 上个月 = 100+200 = 300

在这种情况下，两者相同，但在实际数据中，每个月的收入不同。

Answer 1

我从代码中看到“日期”表有一个名为“月份”的数字列，我假设它与“主表”中的“周一”列的类型相同。

另外，由于在“主表”中没有年份，我假设不考虑年份。

从日期表的切片器中，我们可以使用 SELECTEDVALUE() 直接获取选定的“日期”[月份]。我们使用 TODAY() 函数获取的当前月份作为默认参数。

然后我们从 Selected Month 中减去一个 Previous Month，我们可以使用它来对按 CustomerName、Mon 和 Revenue 分组的表进行切片。需要分组来删除同一客户在同一个月的重复收入，并使用 SUMMARIZE() 实现

作为最后一步，我们可以使用 SUMX 聚合过滤和分组表的“主表”[Revenue]。

'Measure Previous Month Revenue' = 
VAR CurrentMonth =
    MONTH(
        TODAY()
    )
VAR SelectedMonth =
    SELECTEDVALUE(
        'Date'[Month],
        CurrentMonth
    )
VAR PrevMonth = SelectedMonth - 1   
VAR MyTable =
    CALCULATETABLE(
        SUMMARIZE(
            'Main Table',
            'Main Table'[ClientName],
            'Main Table'[Mon],
            'Main Table'[Revenue]
        ),
        'Main Table'[Mon] = PrevMonth,
        REMOVEFILTERS( 'Date' )
    )
VAR Result =
    SUMX(
        MyTable,
        'Main Table'[Revenue]
    )
RETURN
    Result

可以为当前月份编写相同的代码，但用于上一月份的计算

'Measure Current Month Revenue' = 
VAR CurrentMonth =
    MONTH(
        TODAY()
    )
VAR SelectedMonth =
    SELECTEDVALUE(
        'Date'[Month],
        CurrentMonth
    )
VAR MyTable =
    CALCULATETABLE(
        SUMMARIZE(
            'Main Table',
            'Main Table'[ClientName],
            'Main Table'[Mon],
            'Main Table'[Revenue]
        ),
        'Main Table'[Mon] = SelectedMonth,
        REMOVEFILTERS( 'Date' )
    )
VAR Result =
    SUMX(
        MyTable,
        'Main Table'[Revenue]
    )
RETURN
    Result

可以通过设置“日期”表和“主表”之间的关系来实施更好的解决方案。 根据业务需求，可以使用月级别粒度的 Date 表，使用 YearMonth 列而不是 Mon，或者在 Day 级别，使用 Date 列而不是 Mon 列。

Answer 2

CALCULATE 不会影响您已经定义的变量，因此 FILTER 对第一个 SUMX 没有任何作用。请参阅this related post 了解更多详细信息。

---

我建议更简单地编写度量。像这样的：

Previous Month Revenue =
VAR PrevMonth =
    SELECTEDVALUE (
        'Date'[Month],
         MONTH ( TODAY () )
    ) - 1
RETURN
    CALCULATE (
        SUM ( 'Main Table'[Revenue] ),
        'Main Table'[Mon] = PrevMonth
    )