是否有内置函数可以获取 Haskell 中列表的所有大小为 n 的连续子序列？

Question

例如，我需要一个函数：

gather :: Int -> [a] -> [[a]]
gather n list = ???

gather 3 "Hello!" == ["Hel","ell","llo","ol!"].

我有一个可行的实现：

gather :: Int-> [a] -> [[a]]
gather n list = 
    unfoldr 
        (\x -> 
            if fst x + n > length (snd x) then 
                Nothing 
            else 
                Just 
                    (take 
                        n 
                        (drop 
                            (fst x)
                            (snd x)), 
                    (fst x + 1, snd x))) 
        (0, list)

但我想知道语言中是否已经为此内置了一些东西？我扫描了 Data.List 但什么也没看到。

Answer 1

你可以使用tails:

gather n l = filter ((== n) . length) $ map (take n) $ tails l

或使用takeWhile 代替filter：

gather n l = takeWhile ((== n) . length) $ map (take n) $ tails l

编辑：您可以按照 cmets 中的建议删除从 tails 返回的列表的最后一个 n 元素来删除过滤步骤：

gather n = map (take n) . dropLast n . tails
  where dropLast n xs = zipWith const xs (drop n xs)

Answer 2

由于zipping的属性，可以自动安排尾巴的掉落，

import Data.List (tails)

g :: Int -> [a] -> [[a]]
g n = foldr (zipWith (:)) (repeat []) . take n . tails

否则一个简单的transpose . take n . tails 就足够了。测试：

前奏曲数据列表> g 3 [1..10]
[[1,2,3],[2,3,4],[3,4,5],[4,5,6],[5,6,7],[6,7,8],[ 7,8,9],[8,9,10]]
Prelude Data.List> 转置。取 3 。尾巴 $ [1..10]
[[1,2,3],[2,3,4],[3,4,5],[4,5,6],[5,6,7],[6,7,8],[ 7,8,9],[8,9,10],[9,10],[10]]

---

(edit 2018-09-16:) zipping 的使用可以在更高层次上表达，用traverse ZipList:

g :: Int -> [a] -> [[a]]
g n = getZipList . traverse ZipList . take n . tails