在 Clojure 测试中存根 HTTP 请求的策略

Question

我想知道在 Clojure 集成测试中是否有广泛使用的模式或解决方案来存根对第三方的出站 HTTP 请求（如 Ruby 的 webmock）。我希望能够在高级别（例如，在 setup 函数中）存根请求，而不必将我的每个测试都包装在 (with-fake-http [] ...) 之类的东西中，也不必求助于依赖注入。

这对于动态变量来说是一个很好的用例吗？我想我可以在设置步骤中进入有问题的命名空间，并将副作用函数设置为无害的匿名函数。但是，这感觉很重，我不喜欢更改我的应用程序代码以适应我的测试的想法。 （它也不比上面提到的解决方案好多少。）

换入包含假函数的特定于测试的 ns 是否有意义？在我的测试中是否有一种干净的方法可以做到这一点？

Answer 1

前段时间我也遇到过类似的情况，但我找不到任何能满足我需求的 Clojure 库，因此我创建了自己的库，名为 Stub HTTP。使用示例：

(ns stub-http.example1
  (:require [clojure.test :refer :all]
            [stub-http.core :refer :all]
            [cheshire.core :as json]
            [clj-http.lite.client :as client]))

(deftest Example1  
    (with-routes!
      {"/something" {:status 200 :content-type "application/json"
                     :body   (json/generate-string {:hello "world"})}}
      (let [response (client/get (str uri "/something"))
            json-response (json/parse-string (:body response) true)]
        (is (= "world" (:hello json-response))))))

Answer 2

你可以看到一个使用 ring/compojure 框架的好例子：

> lein new compojure sample
> cat  sample/test/sample/handler_test.clj


(ns sample.handler-test
  (:require [clojure.test :refer :all]
            [ring.mock.request :as mock]
            [sample.handler :refer :all]))

(deftest test-app
  (testing "main route"
    (let [response (app (mock/request :get "/"))]
      (is (= (:status response) 200))
      (is (= (:body response) "Hello World"))))

  (testing "not-found route"
    (let [response (app (mock/request :get "/invalid"))]
      (is (= (:status response) 404)))))

更新

对于出站 http 调用，您可能会发现 with-redefs 很有用：

(ns http)

(defn post [url]
  {:body "Hello world"})

(ns app
  (:require [clojure.test :refer [deftest is run-tests]]))

(deftest is-a-macro
  (with-redefs [http/post (fn [url] {:body "Goodbye world"})]
    (is (= {:body "Goodbye world"} (http/post "http://service.com/greet")))))

(run-tests) ;; test is passing

在此示例中，原始函数 post 返回“Hello world”。在单元测试中，我们使用返回“再见世界”的存根函数临时覆盖post。

完整文档is at ClojureDocs。