如何获得自动生成的 gnuplot 抽动之间的距离？

Question

我正在使用 gnuplot 进行大量绘图。由于每个图的数据范围（对于 x 和 y 轴）都是可变的，我需要让 gnuplot 自动设置范围和抽动。但是，我需要在绘图下方放置一个已定义的网格，水平线每个 1/8 单位，垂直线 1/4 单位。当我让 gnuplot 决定在哪里放置 tic 时，我不知道两个 tic 之间的距离（以单位为单位），因此，我不知道我应该在 m{x|y}tics 中进行的细分数量所需的输出。

例如：如果我每两个单位有一个 ytic，我需要“设置 mytics 8”。如果我每个单位都有一个 ytic，我需要“设置 mytics 4”。

那么，有办法获得自动放置的抽动之间的距离吗？甚至是绘制的抽动次数？

Answer 1

要获取自动放置的抽动之间的距离，请使用以下代码（另存为ticstep.gp）：

xr = abs(max_value - min_value)
power = 10.0 ** floor(log10(xr))
xnorm = xr / power # approximate number of decades
posns = 20.0 / xnorm;

if (posns > 40) {
  tics = 0.05
} else {
  if (posns > 20) {
    tics = 0.1
  } else {
    if (posns > 10) {
      tics = 0.2
    } else {
      if (posns > 4) {
        tics = 0.5
      } else {
        if (posns > 2) {
          tics = 1
        } else {
          if (posns > 0.5) {
            tics = 2
          } else {
            tics = ceil(xnorm)
          }
        }
      }
    }
  }
}
ticstep = tics * power

这应该等同于确定 ticstep 的内部 gnuplot 代码（参见 axis.c, line 677。

仅获取ticstep，您可以使用stats获取相应的数据值：

stats 'file.txt' using 1 noutput
max_value = STATS_max
min_value = STATS_min
load 'ticstep.gp'
print ticstep

要获得绘制的抽动数，您需要自动扩展轴限制（除非您使用set autoscale fix）。为此，您可以使用unknown 终端进行绘图以获取例如GPVAL_Y_MAX 和 GPVAL_Y_MIN:

set terminal push # save current terminal
set terminal unknown
plot 'file.txt' using 1
set terminal pop # restore terminal
max_value = GPVAL_Y_MAX
min_value = GPVAL_Y_MIN
load 'ticstep.gp'

print sprintf('ticstep = %f', ticstep)
numtics = int((xr / ticstep) + 1)
print sprintf('numtics = %d', numtics)