使用 Gnuplot 的堆叠和分组条形直方图

Question

我想重现像this one 这样的条形图，即：多个组，每个组有许多条（在我的情况下为 4 个条），每个条被分割成几片（在我的情况下为两片）。

在我的例子中，我有四种算法应用于不同大小的向量（2^0 到 2^20）。每个算法都有两个“部分”，本地计算和通信。对于每个向量大小，我想显示每个算法执行本地计算和通信所需的时间，以及对应于这两个部分总和的总时间。

因此，我希望为每个矢量大小设置一个组。在每组中，有四个条形对应于四种算法，每个条形被分割为（例如）对应于本地计算的红色部分和对应于通信的蓝色部分。

这对 gnuplot 可行吗？我可以提供任何有用格式的数据。

非常感谢。

Answer 1

对于您的数据集，堆叠本地和通信部分没有意义，因为通信部分太小而无法在图表中看到。在任何情况下，根据进一步的要求（图例条目、刻度标签等），组合堆叠和集群也是非常棘手的。

以下是如何为您的数据集绘制聚类直方图的示例：

set style histogram clustered gap 1
set style data histogram
set style fill solid 1.0 noborder

set termoption enhanced

set xtics out nomirror

myxtic(x) = sprintf('2^{%d}', int(floor(log(x)/log(2) + 0.5)))
plot 'test.dat' using ($2+$3):xtic(myxtic(stringcolumn(1))) title 'Algorithm 1',\
     for [i=2:4] '' using (column(2*i)+column(2*i+1)) title sprintf('Algorithm %d', i)

结果是：

要按算法分组，您可以使用newhistogram 关键字创建新组：

set style histogram rowstacked title offset 4,1
set boxwidth 0.9 relative
set style fill solid 1.0 border lt -1
set xtics rotate by 90 right
plot newhistogram "Algorithm 1" lt 1,\
     'test.dat' using 2:xtic(1) title columnheader, \
     '' using 3 title columnheader,\
     newhistogram "Algorithm 2" lt 1,\
     'test.dat' using 4:xtic(1) notitle, \
     '' using 5 notitle,\
     newhistogram "Algorithm 3" lt 1,\
     'test.dat' using 6:xtic(1) notitle, \
     '' using 7 notitle,\
     newhistogram "Algorithm 4" lt 1,\
     'test.dat' using 8:xtic(1) notitle, \
     '' using 9 notitle

local 和 comm 数据是堆叠在一起的，但 comm 部分太小了，以至于您无法在图表中看到它（仅当您放大时）。

对于我使用 4.6.3 和以下设置的输出：

set terminal pngcairo size 1000,400
set output 'test.png'
set xtics font ',6'

结果是：

更复杂的 xtics 显示需要一些技巧，因为对于直方图，xtics 不被视为数字，而是字符串。这是一个例子：

set terminal pngcairo size 1000,400
set output 'test.png'

set style histogram rowstacked title offset 0,-0.5
set bmargin 3
set boxwidth 0.9 relative
set style fill solid 1.0 border lt -1
set termoption enhanced
set xtics out nomirror
myxtic(x) = (int(floor(log(x)/log(2) + 0.5)) % 5 == 0) ? sprintf('2^{%d}', int(floor(log(x)/log(2) + 0.5))) : ""

plot newhistogram "Algorithm 1" lt 1,\
     'test.dat' using 2:xtic(myxtic(real(stringcolumn(1)))) title columnheader, \
     '' using 3 title columnheader,\
     newhistogram "Algorithm 2" lt 1,\
     'test.dat' using 4:xtic(myxtic(real(stringcolumn(1)))) notitle, \
     '' using 5 notitle,\
     newhistogram "Algorithm 3" lt 1,\
     'test.dat' using 6:xtic(myxtic(real(stringcolumn(1)))) notitle, \
     '' using 7 notitle,\
     newhistogram "Algorithm 4" lt 1,\
     'test.dat' using 8:xtic(myxtic(real(stringcolumn(1)))) notitle, \
     '' using 9 notitle

结果