如何检查字形是否是字母？

Question

我如何检查字形是否是字母（或经常在单​​词中使用的东西，如象形文字）？

查看 Elixir 的 String 文档后，我看到的唯一方法是检查 String.downcase 和 String.upcase 是否返回相同的字符串。如果他们这样做了，那么字形就不是用在单词中的东西了。

我就是这样做的，但肯定应该有更简单的方法吗？

defmodule Words do
  defp all_letters_uppercase?(string) do
    String.upcase(string) == string
  end

  defp all_letters_downcase?(string) do
    String.downcase(string) == string
  end

  defp contains_letter?(string) do
    not (all_letters_uppercase?(string) and all_letters_downcase?(string))
  end

  def single_grapheme?(string) do
    with graphemes = String.graphemes(string)
    do
      length(graphemes) == 1 and hd(graphemes) == string
    end
  end

  @doc """
  Check whether string is a single letter.
  """
  def letter?(string) do
    single_grapheme?(string) and contains_letter?(string)
  end
end

更新：我的代码不适用于日文字母

iex(35)> Words.letter?("グ")            
false

Answer 1

您可以使用正则表达式来检查一些 unicode 功能，其中之一是\p{Letter}，或简称为\p{L}。您可能想要添加 \p{Mark}* 或 \p{M}* 以匹配多个以下组合变音符号。这将与String.graphemes/1 中的逻辑非常匹配。请务必在正则表达式之后添加 u 修饰符以启用这些 Unicode 功能。例如：

iex> String.match?("グ", ~r/\A\p{L}\p{M}*\z/u)
true

另见http://erlang.org/doc/man/re.html，“Unicode 字符属性”部分和http://www.regular-expressions.info/unicode.html#grapheme。

Answer 2

这似乎工作正常：

defmodule Words do
  def letter?(string) do
    Regex.match?(~r/^\p{L}$/fu, string)
  end
end


iex(51)> Words.letter?("a")
true
iex(52)> Words.letter?("é")
true
iex(53)> Words.letter?("グ")
true
iex(54)> Words.letter?("aa")
false
iex(55)> Words.letter?("1") 
false
iex(56)> Words.letter?("-")
false
iex(57)> Words.letter?("") 
false
iex(58)> Words.letter?(" ")
false
iex(59)> Words.letter?("éé")
false
iex(60)> Words.letter?("a ")
false