Stata - 使用 XML_Tab 导出 F 测试结果

Question

我正在尝试导出 F 统计量和 Prob > F 以进行 2 次系数测试（每个测试都有许多回归）。我正在使用 xml_tab 将回归结果导出到 excel 中。我已经能够将 F-stat 和概率 [ r(p) 和 r(F) ] 的结果存储为本地变量，但无法找到一种方法来自动化该过程，以便这些结果显示在我的整体回归中在 xml_tab 中。我知道这是一个用户编写的命令，但想知道是否有人想出了一个黑客。我不想“复制粘贴”，因为有 2 个测试和如此多的回归（我有更多），我想尽量减少人为错误。我的代码结构如下。

reg y x control1 control2 control3, robust plus
estimates store model_1
test control1 = control2
local p_1=r(p)
local f_1=r(F)
test control1 = control3
local p_2=r(p)
local f_2=r(F)
local x = upper(word(c(current_date),1)+word(c(current_date),2)+word(c(current_date),3))
    xml_tab author_model_1 ///
    "C:\Users\analysis_(`x').xml", ///
    replace nolabel below tstat ///
    format((S2110) (SCCB0 NCCR3 NCCR2)) ///
    keep(y x control1 control2 control3) ///
    stats(N r2 r2_a p) ///
    sheet("Analysis") ///
    title("Analysis") /// 
    cwidth(0 100, 1 80, 2 80, 3 80) ///
    cnames("Basic Regression")

Answer 1

您的代码有几个错误：

1.xml_tab命令的语法是：

xml_tab [namelist] [, options]

其中namelist“是存储的估计或矩阵的列表”。您的 author_model_1 不符合该要求。

2.要输出的.xml文件必须用选项save(["]filename["])指定 你也不遵守。

3.您的keep() 选项包含因变量，但keep() 旨在处理系数。因变量没有系数。

以下代码有效（只需更改输出目录）

clear all
set more off

sysuse auto

reg price mpg weight length, robust plus
estimates store model

local x = upper(word(c(current_date),1)+word(c(current_date),2)+word(c(current_date),3))
display "`x'"

xml_tab model, ///
    save("D:\USER\Desktop\myfile_(`x').xml") ///
    replace nolabel below tstat ///
    format((S2110) (SCCB0 NCCR3 NCCR2)) ///
    keep(mpg weight length) ///
    stats(N r2 r2_a p) ///
    sheet("Analysis") ///
    title("Analysis") /// 
    cwidth(0 100, 1 80, 2 80, 3 80) ///
    cnames("Basic Regression")

这一切只需查看help xml_tab即可解决。

根据其帮助文件，该命令只允许存储估计结果（使用estimates store）和矩阵。 例如，如果您想导出test 的结果（estimates store 将不保存），那么您可以将其结果保存到矩阵并将其输入xml_tab。然而，一些测试表明你不能同时喂两个，所以必须打两个电话。第一个用于所有存储的估计结果；所有矩阵的第二个。这样的工作：

clear all
set more off

sysuse auto

reg price mpg weight length, robust plus
estimates store model

test mpg = weight
matrix p1 = r(p)
matrix f1 = r(F)

test mpg = length
matrix p2 = r(p)
matrix f2 = r(F)

local x = upper(word(c(current_date),1)+word(c(current_date),2)+word(c(current_date),3))

xml_tab model, save("D:\USER\Desktop\myfile_(`x').xml") replace
xml_tab p1 f1 p2 f2, save("D:\USER\Desktop\myfile_(`x').xml") append

结果分布在两张表中（使用 MS Excel 打开时）。我发现你所追求的输出很笨拙，但我不是使用 xml_tab 命令的专家。您可能想探索 Stata 内置命令（xml_tab 是来自 SSC 的用户编写的命令）。要直接导出到电子表格，请尝试help export excel、help putexcel。如需更多通用选项，请尝试help export。对于允许导出结果的流行用户编写命令，请尝试 ssc describe estout 和 ssc describe tabout。