Stata：通配符在 egen 函数中有例外

Question

我是使用宏的新手，我想将此 "Wildcard with exceptions" syntax 合并到 Stata 12 中的 egen 函数中。我想做一些类似的事情：

foreach i in E F G {
    unab all`i' : V_`i'*
    unab excl`i' : V_`i'9*
    local general`i' : list all`i' - excl`i'
} 

egen Exp_operating = rowtotal(`generalE')
egen Exp_capital = rowtotal(`generalF' `generalG') 

换句话说，我想创建一个 V_E* 的变量列表，其中不包括变量 V_E9*，然后为每个观察创建一个等于该列表中每个变量的总和的变量。但是，执行egen 命令后出现语法错误。有人可以帮我弄清楚如何做我想做的事吗？

Answer 1

一些技术代码：

clear all
set more off

*----- example data -----

set obs 1

gen V_E1 = 1
gen V_E2 = 2
gen V_E22 = 2
gen V_E3 = 3

gen V_F1 = 3
gen V_F2 = 4
gen V_F22 = 4
gen V_F3 = 5

*----- what you seek -----

foreach i in E F {
    unab all`i' : V_`i'*
    unab excl`i' : V_`i'2*
    local general`i' : list all`i' - excl`i'
} 

* display contents of macros 
display "`generalE'"
display "`generalE' `generalF'"

* sum of V_E1 V_E3
egen Exp_operating = rowtotal(`generalE')

* sum of V_E1 V_E3 V_F1 V_F3
egen Exp_capital = rowtotal(`generalE' `generalF') 

list

在将宏传递给egen 之前，使用display 检查宏的内容。