Stata：从 Excel 导入时以小写重命名变量

Question

我正在尝试导入一个 Excel 工作表，该工作表具有混合了大写和小写字母的变量名。我希望 Stata 将它们全部读取为小写，但是当我输入 case(lower) 选项时，Stata 返回 option case() not allowed。

这是我尝试输入的内容：

import excel "/Users/p/D/B/File name/", sheet("Sheet1") firstrow case(lower)

当我不使用case() 选项时，import 命令可以正常工作。有人可以告诉我我做错了什么吗？

Answer 1

我发现很难重现您的问题，但下面是一个使用各种case() 选项（基本上来自help import excel）的工作示例：

clear all
set more off


*----------------- Create data -----------------------------

* Load example Stata data base
sysuse auto
keep make price headroom length turn

* Change variable names to experiment
rename (headroom length turn) (HEADRoom LENGTH turN)

* Create example Excel file
export excel auto, firstrow(variables) replace


*----------------- Importing -------------------------------

* Import just as it is
import excel auto.xls, firstrow clear
describe

* Import with upper case
import excel auto.xls, firstrow case(upper) clear
describe

* Import with lower case
import excel auto.xls, firstrow case(lower) clear
describe

请注意，它们都工作正常。变量 names 相应地转换为大写/小写。变量 labels 不是，但这是意料之中的。来自help import excel 我们有：

第一行中的原始名称未修改地存储为变量 标签。

和case()仅影响变量名。

你还提到：

当我不使用case() 选项时，导入命令可以正常工作。

假设这是真的。然后导入后将变量名转为小写，可以试试

rename _all, lower

详情请见help rename group。 （但就像我展示的那样，case() 选项有效。）

最后，如果它是变量 labels 你所追求的，你可以使用类似的东西来改变它们

foreach varr of varlist _all {
    label variable `varr' "`varr'"
}

这只是将所有变量的变量名称复制到标签。因此，在所有变量名都转换为小写字母之后运行它会为您提供也是小写字母的变量标签。运行help label了解详情。