Stata替换字符串的一部分

Question

我有 10 位长字符串“0000000000”，称为my_var。我有两个变量 highclass（介于 0 和 10 之间）和 lowclass（介于 0 和 10 之间）。

我需要将highclass 和lowclass 之间的数字转换为1。

例如，如果一行有highclass =5 和lowclass =1，那么my_var 应该变成1111100000。

我不确定 substring 命令是否对我有帮助，因为我需要引用一个变量。

Answer 1

据我了解，lowclass 是第一个1 的位置，highclass 是最后一个1 的位置。

不需要循环。事实上，在 Stata 中（这是问题所涉及的语言）中的单个语句就可以做到这一点。

两种方法：

旧式（尤其适用于 Stata 12 及更低版本）

在这里，我将单个语句拆分为多个，因为我怀疑这样会更清楚。注意substr()（不是substring()）是一个函数，而不是一个命令。

clear 
input str10 my_var lowclass highclass 
"0000000000"  1  5
"0000000000"  2  4
"0000000000"  3  3 
"0000000000"  1  10
"0000000000"  7  10 
end 

local zeros "0000000000"
local ones  "1111111111" 
replace my_var = substr("`zeros'", 1, lowclass - 1)
replace my_var = my_var + substr("`ones'", 1, highclass - lowclass + 1) 
replace my_var = my_var + substr("`zeros'", 1, 10 - highclass) 

list 

     +----------------------------------+
     |     my_var   lowclass   highcl~s |
     |----------------------------------|
  1. | 1111100000          1          5 |
  2. | 0111000000          2          4 |
  3. | 0010000000          3          3 |
  4. | 1111111111          1         10 |
  5. | 0000001111          7         10 |
     +----------------------------------+

新风格（Stata 13 以上）

Mata 和 Stata 13 up 允许字符串乘法，（例如10 * "1"）所以这有效：

replace my_var = (lowclass - 1) * "0" + (highclass - lowclass + 1) * "1" + (10 - highclass) * "0" 

请注意，例如-1 * "0" 完全合法，但评估为缺失（空字符串）。