使用 Parsec 的带引号字符串的解析器

Question

我想解析这样的输入字符串："this is \"test \" message \"sample\" text"

现在，我编写了一个解析器，用于解析不带引号的单个文本：

parseString :: Parser String
parseString = do
  char '"'
  x <- (many $ noneOf "\"")
  char '"'
  return x

这会解析像这样的简单字符串："test message"

然后我为带引号的字符串写了一个解析器：

quotedString :: Parser String
quotedString = do
  initial <- string "\\\""
  x <- many $ noneOf "\\\"" 
  end <- string "\\\""
  return $ initial ++ x ++ end

这样的字符串解析器：\"test message\"

有没有一种方法可以将两个解析器结合起来，从而获得我想要的目标？解决这个问题的具体方法是什么？

Answer 1

这就是我要做的：

escape :: Parser String
escape = do
    d <- char '\\'
    c <- oneOf "\\\"0nrvtbf" -- all the characters which can be escaped
    return [d, c]

nonEscape :: Parser Char
nonEscape = noneOf "\\\"\0\n\r\v\t\b\f"

character :: Parser String
character = fmap return nonEscape <|> escape

parseString :: Parser String
parseString = do
    char '"'
    strings <- many character
    char '"'
    return $ concat strings

现在你需要做的就是调用它：

parse parseString "test" "\"this is \\\"test \\\" message \\\"sample\\\" text\""

解析器组合器起初有点难以理解，但一旦你掌握了它，它们就会比编写 BNF 语法更容易。

Answer 2

quotedString = do
    char '"'
    x <- many (noneOf "\"" <|> (char '\\' >> char '\"'))
    char '"'
    return x

我相信，这应该可行。

Answer 3

如果有人正在寻找更开箱即用的解决方案，this answer in code-review 正好提供。这是一个正确导入的完整示例：

import           Text.Parsec
import           Text.Parsec.Language
import           Text.Parsec.Token

lexer :: GenTokenParser String u Identity
lexer = makeTokenParser haskellDef

strParser :: Parser String
strParser = stringLiteral lexer

parseString :: String -> Either ParseError String
parseString = parse strParser ""

Answer 4

我想解析带引号的字符串并删除在解析步骤中用于转义的任何反斜杠。在我的简单语言中，唯一可转义的字符是双引号和反斜杠。这是我的解决方案：

quotedString = do
  string <- between (char '"') (char '"') (many quotedStringChar)
  return string
  where
    quotedStringChar = escapedChar <|> normalChar
    escapedChar = (char '\\') *> (oneOf ['\\', '"'])
    normalChar = noneOf "\""

Answer 5

我更喜欢以下内容，因为它更易于阅读：

quotedString :: Parser String
quotedString = do
    a <- string "\""
    b <- concat <$> many quotedChar
    c <- string "\""
    -- return (a ++ b ++ c) -- if you want to preserve the quotes
    return b
    where quotedChar = try (string "\\\\")
                   <|> try (string "\\\"")
                   <|> ((noneOf "\"\n") >>= \x -> return [x] )

Aadit 的解决方案可能更快，因为它不使用try，但它可能更难阅读。

请注意，它与 Aadit 的解决方案不同。我的解决方案忽略了字符串中的转义内容，只关心\" 和\\。

例如，假设您的字符串中有一个制表符。 我的解决方案成功地将"\"\t\"" 解析为Right "\t"。 Aadit 的解决方案是 unexpected "\t" expecting "\\" or "\""。

另请注意，Aadit 的解决方案仅接受“有效”转义。例如，它拒绝"\"\\a\""。 \a 不是有效的转义序列（根据man ascii，它代表系统铃声并且有效）。我的解决方案只返回Right "\\a"。

所以我们有两个不同的用例。

• 我的解决方案：用可能转义的引号和转义的转义符解析带引号的字符串

• Aadit 的解决方案：使用有效转义序列解析带引号的字符串，其中有效转义表示 "\\\"\0\n\r\v\t\b\f"

Answer 6

详细说明@Priyatham 的回应

pEscString::Char->Parser String
pEscString e= do
  char e;
  s<-many (
    do{char '\\';c<-anyChar;return ['\\',c]}
    <|>many1 (noneOf (e:"\\")))
  char e
  return$concat s