Groovy 收集嵌套元素和外部元素

Question

使用 Groovy，要求是收集地图的嵌套元素值及其顶级元素值。

不确定是否需要递归方法。

示例 JSON

{
"items": [
      {
      "attribute": "Type",
      "options":       
      [
                  {
            "label": "Type1",
            "value": "1"
         },
                  {
            "label": "Type2",
            "value": "2"
         }

      ]
   },
      {
      "attribute": "Size",
      "options":       [
                  {
            "label": "SizeA",
            "value": "A"
         },
                  {
            "label": "SizeB",
            "value": "B"
         }
      ]
   }
]
}

收集后的预期输出

[
{attribute=Type,label=Type1,value=1},
{attribute=Type,label=Type2,value=2},
{attribute=Size,label=SizeA,value=A},
{attribute=Size,label=SizeB,value=B}
]

Answer 1

您可以使用collectMany 组合通过collect 方法获得的多个options 列表来解决此问题。

见下面sn-p的代码：

def input = """
{
  "items": [
    {
      "attribute": "Type",
      "options": [
         {
           "label": "Type1",
           "value": "1"
         },
         {
           "label": "Type2",
           "value": "2"
         }
      ]
   },
   {
     "attribute": "Size",
     "options": [
         {
            "label": "SizeA",
            "value": "A"
         },
         {
            "label": "SizeB",
            "value": "B"
         }
     ]
  } ]
}"""

def json = new groovy.json.JsonSlurper().parseText(input)

/* collectMany directly flatten the two sublists 
 * [ [ [ type1 ], [ type2 ] ], [ [ sizeA ], [ sizeB ] ] ]
 * into
 * [ [type1], [type2], [sizeA], [sizeB] ]
 */
def result = json.items.collectMany { item ->
    // collect returns a list of N (in this example, N=2) elements 
    // [ [ attribute1: ..., label1: ..., value1: ... ],
    //   [ attribute2: ..., label2: ..., value2: ... ] ]
    item.options.collect { option ->
        // return in [ attribute: ..., label: ..., value: ... ]
        [ attribute: item.attribute ] + option
    }
}

assert result == [
    [ attribute: "Type", label: "Type1", value: "1" ],
    [ attribute: "Type", label: "Type2", value: "2" ],
    [ attribute: "Size", label: "SizeA", value: "A" ],
    [ attribute: "Size", label: "SizeB", value: "B" ],
]

Answer 2

感谢朱塞佩！ 我已经用一种不那么时髦的方法解决了这个问题：

def result  = [];//Create new list with top-level element and nested elements
json.items.each {item ->
    result.addAll(item.options.collect{ option ->
        [attribute: /"${item?.attribute?:''}"/, label: /"${option?.label?:''}"/, value: /"${option?.value?:''}"/ ]
    })
};