如果一个范围大于谷歌表格中的 Countifs 函数中的另一个范围，如何放置？

Question

我需要一个特定球员在联赛中获胜次数的公式。 所以我需要计算一名球员的所有胜利，为此，我需要计算进球的范围，并且该范围必须大于预期的进球数才能算作胜利。

我试过这个公式，但它不起作用：

=Countifs(K7:K19,"Nikolinho Pueblo Jr.",L7:M19, L7:L19>M7:M19 )

有人可以帮我吗？

谢谢

Answer 1

已编辑：在末尾添加了 IFERROR 公式，并根据 cmets 扩展为 2 个末端。

您可以从查询中计算返回的项目：

=COUNTA( QUERY( K7:M19,"select K where K = 'Nikolinho Pueblo Jr.' and L > M", 0))

这样，如果需要，您可以用单元格引用替换值，还可以打开范围以转到最后一行：

=COUNTA( QUERY( K7:M,"select K where K = '" & B2 & "' and L > M", 0))

这将给出单元格 B2 中名称的计数。

为了不计算不返回结果（返回错误）的查询，请使用以下命令：

=COUNTA( IFERROR( QUERY( L7:N,"select N where N = '" & J1 & "' and M > L", 0),), IFERROR( QUERY( K7:M,"select K where K = '" & J1 & "' and L > M", 0),))

添加： 要从 2 列中检查获胜者，您可以在 COUNTA 中放置 2 个查询公式，例如：

=COUNTA( IFERROR( QUERY( L7:N,"select N where N = '" & A10 & "' and M > L", 0),), IFERROR( QUERY( K7:M,"select K where K = '" & A10 & "' and L > M", 0),))

您也可以通过一个查询来做到这一点：

=COUNTA( QUERY( K7:N,"select K where (K = '" & A10  & "' and L > M) or (N = '" & A10 & "' and M > L) ", 0))

Answer 2

您想先将出现在列K 中的玩家的获胜次数与右侧的得分进行比较，然后将右侧的获胜次数与玩家出现的左侧的得分进行比较来累加在N 列中。

更新公式：

=SUMPRODUCT(($K$7:$K$19="Nikolinho Pueblo Jr.")*($L$7:$L$19>$M$7:$M$19))+SUMPRODUCT(($N$7:$N$19="Nikolinho Pueblo Jr.")*($M$7:$M$19>$L$7:$L$19))