SAS-在不满足条件的情况下添加零

Question

对此的任何帮助将不胜感激。我正在尝试根据特定 ID 是否提交特定代码为我的数据添加“0”值。为了更好地说明我在这里尝试做的是一个示例数据集，其中应该表示三个 ID 和三个代码，然后是我想要的。

ID    Submitted_Code  Times_Submitted    Cost_Per_Each
A      42              10                  15.00
A      43               5                  30.00
B      44               6                  35.00
C      42               5                  15.00
C      43               7                  30.00
C      44               8                  35.00

对于每个未提交代码的 ID，将显示未提交的代码，后跟零表示提交的次数。就这样

   ID    Submitted_Code  Times_Submitted    Cost_Per_Each
    A      42              10                  15.00
    A      43               5                  30.00
    A      44               0                  35.00
    B      42               0                  15.00
    B      43               0                  30.00
    B      44               6                  35.00
    C      42               5                  15.00
    C      43               7                  30.00
    C      44               8                  35.00

谢谢！

Answer 1

感谢大家的帮助和建议，我能够使用上述建议的补丁，使用稀疏函数然后使用左连接重新加入来做到这一点。再次感谢所有建议。

 /*Creating a table that creates all possible Combinations of Provider-Revenue Code for all Provider showing up in data*/
    proc freq data=ID_Code_breakdown noprint;
    tables ID*Code/sparse out=want(drop=percent);
    run;

/*Then merge with main table to get all possible combinations*/
    PROC SQL;
    CREATE TABLE LEFT1 AS
    SELECT A.*, B.HIC_COUNT, B.Amount_Total_Paid
    FROM want A LEFT JOIN ID_code_breakdown B
    ON A.Id = B.Id AND A.Code = B.Code
    ORDER BY Id;
    quit;

/*Replace missing value .'s with 0's*/
    data LEFT2;                 
       set LEFT1;               
       array change _numeric_;
                do over change;
                if change=. then change=0;
                end;
       run;

Answer 2

我想你有两张桌子。一个带有提交的代码（假设表已提交）和另一个主表具有所有可能的 ID 和提交的代码（假设表主）。以下代码是创建示例数据

data submitted;
  input ID $1 Submitted_Code Times_Submitted;
datalines;
  A 42 10
  A 43 5
  B 44 6
run;

data master;
  input ID $1 Submitted_Code ;
datalines;
  A 42
  A 43
  A 44
  B 42
  B 44
run;

然后您可以使用 PROC SQL 将提交的表与主表进行左连接。 coalesce 函数可用于将缺失的 Submitted_Time 值设置为 0。

proc sql;
  create table foo as select 
  a.ID, a.Submitted_Code, Coalesce(b.Times_Submitted,0) As Times_Submitted
  from master a 
  left join submitted b
  on a.ID = b.ID and a.Submitted_Code = b.Submitted_Code;
quit;