线性化 Oracle 嵌套表

Question

如何线性化嵌套表，嵌套表本身也包含嵌套表（注意：内部表的大小可能不同）。假设我有以下类型声明：

CREATE OR REPLACE TYPE VECTOR
IS
  TABLE OF NUMBER;

CREATE OR REPLACE TYPE TABLE_OF_VECTOR
IS
  TABLE OF VECTOR;

以及PL/SQL的以下sn-p：

DECLARE
  number_table TABLE_OF_VECTOR;
  result_vector VECTOR;
BEGIN
  number_table := table_of_vector(vector(23, 4, 2222, 22222222),
    vector(2, 1, 766, 2), vector(2, 1, 5));
END;

有没有一种方法可以线性化 number_table 并将其所有值存储在 result_vector 中作为一个连续的数字列表？我想结束：

result_vector == vector(23, 4, 2222, 22222222, 2, 1, 766, 2, 2, 1, 5)

Answer 1

确实如此，但并不漂亮。

select cast(collect(b.column_value) as vector) 
from  table(table_of_vector(
             vector(23, 4, 2222, 22222222), 
             vector(2, 1, 766, 2), 
             vector(2, 1, 5))) a, 
      table(a.column_value) b;

因此 table(...) 部分将 table_of_vector 视为“常规”表，其中包含名为“COLUMN_VALUE”的列。然后我们将其视为另一个我称之为 B 的表。

SELECTed 表达式获取构成“A”表中的“B”表的所有单个数字，并将它们聚合到一个集合中（使用 COLLECT）。最后，我明确地将集合转换为 VECTOR 类型。

Answer 2

DECLARE
  number_table TABLE_OF_VECTOR;
  result_vector VECTOR:=vector();
BEGIN
  number_table := table_of_vector(vector(23, 4, 2222, 22222222),
    vector(2, 1, 766, 2), vector(2, 1, 5));
for i in number_table.first .. number_table.last loop
   for  j in number_table(i).first .. number_table(i).last loop
     result_vector.extend();
     result_vector(result_vector.count):=number_table(i)(j);
  end loop;
end loop;
for i in 1.. result_vector.count loop
    dbms_output.put_line(result_vector(i));
end loop;
END;
/