有人可以用*非常*简单的术语解释反射包 API 吗？

Question

我很难理解描述反射包的文档/示例。我是一名命令式编程老手，但也是一名 Haskell 新手。可以简单介绍一下吗？

包裹：https://hackage.haskell.org/package/reflection

编辑：致结束此问题的人：这是对 Haskell 反射的初学者介绍。下面的答案很好，其他的也很有用，所以请重新打开。

Answer 1

在最简单的用例中，如果您有一些配置信息希望在一组函数中普遍可用：

data Config = Config { w :: Int, s :: String }

您可以为需要访问配置的函数添加Given Config 约束：

timesW :: (Given Config) => Int -> Int

然后使用值given 来引用当前配置（因此w given 或s given 来引用其字段）：

timesW x = w given * x

还有一些其他功能，有些使用配置，有些不使用：

copies :: Int -> String -> String
copies n str = concat (replicate n str)

foo :: (Given Config) => Int -> String
foo n = copies (timesW n) (s given)

然后您可以在 give 的不同配置下运行计算：

main = do
  print $ give (Config 5 "x") $ foo 3
  print $ give (Config 2 "no") $ foo 4

这类似于：

• 全局定义given :: Config，除非你可以在同一个程序的多个配置下运行计算；

• 将配置作为额外参数传递给每个函数，除非您避免显式接受配置并传递它的麻烦，例如：

  timesW cfg x = w cfg * x
  foo cfg n = copies (timesW cfg n) (s cfg)
  

• 使用 Reader monad，但您不必将所有内容都提升为笨拙的 monad 或应用程序级语法，例如：

  timesW x = (*) <$> asks w <*> pure x
  foo n = copies <$> timesW n <*> asks s
  

完整示例：

{-# LANGUAGE FlexibleContexts #-}

import Data.Reflection

data Config = Config { w :: Int, s :: String }

timesW :: (Given Config) => Int -> Int
timesW x = w given * x

copies :: Int -> String -> String
copies n str = concat (replicate n str)

foo :: (Given Config) => Int -> String
foo n = copies (timesW n) (s given)

main = do
  print $ give (Config 5 "x") $ foo 3
  print $ give (Config 2 "no") $ foo 4