在 Access VBA 中，查找字段名称，将列插入表中

Question

我正在尝试创建一个新表，其中源文件中的字段名称是一个变量。例如，源数据中的ID字段可以是“ID”或“HB_REF_NO”，出生日期可以是DoB、Date of Birth或Date_of_birth

我编写了一个代码来搜索各种字段名称并返回它们所在的列，但我正在努力将这些列中的数据传输到表中

这里是代码，请原谅它无疑是野蛮的方法......

Private Sub cmdCompare_Click()

Set db = CurrentDb()
Set RecordSet1 = db.OpenRecordset("OriginalData")
Dim Fld As DAO.Field
Dim FldArray() As String
Dim i As Integer
Dim j As Integer
Dim SQLCreate As String
Dim SQLInsert As String
Dim s As Integer
Dim d As Integer
Dim b As Integer
Dim p As Integer

j = RecordSet1.Fields.Count - 1
ReDim FldArray(j)

'Assigns field names to the array
For Each Fld In RecordSet1.Fields
    FldArray(i) = Fld.Name
    i = i + 1
Next

For i = 0 To j
    If FldArray(i) = "Surname" Then
        s = i
    Else
    End If
Next

For i = 0 To j
    If FldArray(i) = "HB_REF_NO" Then
        d = i
    Else
    End If
Next

For i = 0 To j
    If FldArray(i) = "NC_DATE_OF_BIRTH" Then
        b = i
    Else
    End If
Next

For i = 0 To j
    If FldArray(i) = "POSTCODE" Then
        p = i
    End If
Next


SQLCreate = "CREATE TABLE OriginalComp" & _
        "(ID varchar(255), Surname varchar(255), DoB varchar(255), Postcode varchar(255))"

DoCmd.RunSQL SQLCreate

SQLInsert = "INSERT INTO OriginalComp (ID, Surname, DoB, Postcode) " & _
      "VALUES ('" & FldArray(d) & "','" & FldArray(s) & "','" & FldArray(b) & "','" & FldArray(p) & "');"

DoCmd.RunSQL SQLInsert

End Sub

Answer 1

检查源表的TableDef.Fields 集合并找到每个变量字段名称的当前名称会更简单。您不需要以Recordset 的形式打开表格，也不需要使用数组。

本示例将查找并使用名称与*Dob* 或*Date*Birth* 匹配的出生日期字段。 （如果表格中有多个字段可以匹配这些模式，则需要替换更具选择性的模式。）

Dim db As DAO.Database
Dim tdf As DAO.TableDef
Dim fld As DAO.Field
Dim strDateOfBirth As String
Dim strInsert As String

Set db = CurrentDb
Set tdf = db.TableDefs("OriginalData")
For Each fld In tdf.Fields
    With fld
        If .Name Like "*DoB*" Or .Name Like "*Date*birth*" Then
            strDateOfBirth = .Name
        End If
    End With
Next

If Len(strDateOfBirth) > 0 Then
    strInsert = "INSERT INTO OriginalComp (ID, Surname, DoB, Postcode) " & _
        "SELECT HB_REF_NO, Surname, [" & strDateOfBirth & "], POSTCODE " & _
        "FROM OriginalData;"
    Debug.Print strInsert '<- inspect this in Immediate window; Ctrl+g will take you there
    db.Execute strInsert, dbFailOnError
Else
    MsgBox "Birth date field not found!"
End If

扩展该示例以处理 HB_REF_NO 与 ID 字段。

Answer 2

问题出在这里：

SQLInsert = "INSERT INTO OriginalComp (ID, Surname, DoB, Postcode) " & _
      "VALUES ('" & FldArray(d) & "','" & FldArray(s) & "','" & FldArray(b) & "','" & FldArray(p) & "');"

FldArray 变量是所有列名的列表，因此 dth 条目将是 dth 列名，这就是您插入列名而不是值的原因！

如果您想将这些值插入到 OriginalComp 中，为什么不这样做：

Private Sub cmdCompare_Click()

Set db = CurrentDb()

SQLCreate = "CREATE TABLE OriginalComp" & _
            "(ID varchar(255), Surname varchar(255), DoB varchar(255), Postcode varchar(255))"

DoCmd.RunSQL SQLCreate

SQLInsert = "INSERT INTO OriginalComp (ID, Surname, DoB, Postcode) " & _
            "SELECT HB_REF_NO, Surname, NC_DATE_OF_BIRTH, POSTCODE " & _
            "FROM OriginalData"

DoCmd.RunSQL SQLInsert

End Sub