批处理变量已损坏[重复]

Question

我正在批量制作聊天室之类的东西。不幸的是，该文件无法存储变量。这是我的代码

@echo off
color b
Title Messanger
:top
echo Are you hosting the chat?
set /p host="Yes or no>"
if /i "%host%"=="yes" (
    set /p port="Port>"
    rem This would normally listen for connections
    echo Listening for connections on port %port%
    pause
 )
if /i "%host%"=="no" (
    echo Who is hosting this chat?
    set /p ip="Ip>"
    set /p port="Port>"
    echo ----------------CHAT----------------
    rem This would normally connect to the ip and port
    echo %ip% %port%
 )
echo Error.
pause
goto top

我不知道你是否得到相同的结果，但只看到没有变量的消息。输出：

Are you hosting the chat?
Yes or no>yes
Port>8080
Listening for connections on port
Press any key to continue . . .

在此之后，它应该会显示回显错误并转到文件的开头

Answer 1

解决方法有两个：

1) 您需要将setlocal enabledelayedexpansion 添加到脚本的开头。像这样：

@echo off
setlocal enabledelayedexpansion
color b
Title Messanger

（注意第 2 行）

2) 然后，在 IF 块内，您需要使用 ! 而不是 % 来寻址变量，如下所示：

if /i "%host%"=="yes" (
    set /p port="Port>"
    rem This would normally listen for connections
    echo Listening for connections on port !port!
    pause
 )

（注意第 4 行）

说明

因为%ip% 和%port% 在子句内（即在括号内），所以它们的值在块内的实际代码执行之前被捕获。在解释器进入IF 块之前，它会在执行此操作之前捕获%port% 的值（在它进入实际块之前不存在）。所以，虽然它看起来你的代码正在运行

echo Listening for connections on port %port%

实际运行的是

echo Listening for connections on port 

（注意空格。%port% 被替换为 %port% 的值在它进入括号内的块之前 - 这是一个空值。

处理被修改然后在一个块中重复使用的变量的解决方案是启用延迟扩展，然后使用! 符号而不是% 来引用它们。