如何从表中获取一行答案

【问题标题】：How to fetch one - one row from table如何从表中获取一行
【发布时间】：2023-03-31 17:30:01
【问题描述】：

我有一张名为stud_ans_sheet 的表。

我想运行一个循环每次都会从表中获取下一个值。

这是一个 PL/SQL 程序，我正在使用游标执行此操作。这是我的程序，但它有很多错误：

set serveroutput on;
declare
    cursor c_stud is select stud_no,ans from stud_ans_sheet;
    v_stud c_stud%rowtype;
    v_no stud_ans_sheet.stud_no%type;
    answer varchar(10);
    i number(3);
    v_corr stud_ans_sheet.corr_ans%type;
    v_wrong stud_ans_sheet.wrong_ans%type;
    v_unattempt stud_ans_sheet.unattempt_ans%type;
    score number(5,2);
    v_ans varchar(10);
    str1 varchar(40);
    str2 varchar(40);
    nval stud_ans_sheet.stud_no%type;
    total number(5,2);
begin
    answer:='AACCABAABD';
    open c_stud;
    loop
        fetch c_stud into v_stud;
        exit when c_stud%notfound;  

        for i in 1..10
        loop

            nval:= select seq.nextval from stud_ans_sheet.stud_no;
            select stud_no,ans into v_no,v_ans from stud_ans_sheet where stud_no=nval;
            str2:=substr(v_ans,i,1);
            str1:=substr(answer,i,1);

            if(str2=str1) then
                update stud_ans_sheet
                set corr_ans=v_corr+1;  
            elsif(str2='E') then
                update stud_ans_sheet
                set unattempt_ans=v_unattempt+1;
            else    
                update stud_ans_sheet
                set wrong_ans=v_wrong+1;        
            end if;

        end loop;           
        update stud_ans_sheet
        set score=corr_ans-wrong_ans*0.25+unattempt_ans;            
    end loop;
    close c_stud;
end;
/

【问题讨论】：

您能否提供一些示例数据-您期望的输入和输出。您的问题并不完全清楚。
我编辑了上面的语句
我必须进行 Mcq 测试...其中 E 表示未尝试。我在表中插入了 10 个值。触发器执行后，我必须找到正确的答案，错误的答案，未尝试的答案，最后必须找到所有 10 个学生的分数
我已经尝试过单身学生并且表现良好，但我需要更新 1 个触发器中的所有字段
您是否遇到任何错误或有什么问题？

标签： plsql plsqldeveloper cursors database-cursor

【解决方案1】：

这行真的没有意义：

nval:= select seq.nextval from stud_ans_sheet.stud_no;

PL/SQL 中没有variable := select ... 构造，即使有，stud_ans_sheet.stud_no 也不是一个表，所以你不能从它select，如果你可以的话，不清楚你想要什么无论如何顺序。

如果您只想将记录属性v_stud.stud_no 复制到局部变量nval 中，那么您可以使用：

nval := v_stud.stud_no;

但问题是，当您可以直接使用v_stud.stud_no 时，为什么要复制它？

当您需要做的只是循环遍历游标时，通常最好避免对游标进行冗长的 declare-open-fetch 构造。相反，您可以使用：

for r in (
    select stud_no, ans from stud_ans_sheet
)
loop

我不明白你为什么在循环中重新查询stud_ans_sheet 只是为了取回你已经拥有的同一行。如果这与您的 update 逻辑有关，我不知道应该做什么。

代码中的update 语句每次都会更新表中的每一行，因为它们没有任何where 子句。

在 PL/SQL 中，if 条件由 then 终止，而不是像在其他一些语言中那样被括在括号中，例如，

if (str2 = str1) then

可以整理成：

if str2 = str1 then

构造for i in 1..10 隐式声明i，其作用域为循环，因此您在顶部声明的另一个i 是不同的变量且未使用。

为了便于阅读，您可以使用空格，所以

update stud_ans_sheet
set score=corr_ans-wrong_ans*0.25+unattempt_ans
where ...

可以更清楚地写成

update stud_ans_sheet
set    score = corr_ans - wrong_ans * 0.25 + unattempt_ans
where  ...;

也许你应该一次只关注一个错误，而不是把整个事情都放在这里供审查。

【讨论】：

好的，我会试试的。感谢您抽出宝贵的时间来回答。
我的表中有 10 行。我想一一更新所有行。如何获取一行？
如何获取一行？游标循环已经一次获取一行。如果您的意思是如何更新一行，则添加where clause。

【解决方案2】：

我修改了你的一些代码，试试这个：

SET SERVEROUTPUT ON;

DECLARE
   ANSWER        VARCHAR (10);
   V_CORR        STUD_ANS_SHEET.CORR_ANS%TYPE;
   V_WRONG       STUD_ANS_SHEET.WRONG_ANS%TYPE;
   V_UNATTEMPT   STUD_ANS_SHEET.UNATTEMPT_ANS%TYPE;
   STR1          VARCHAR (40);
   STR2          VARCHAR (40);
BEGIN
   ANSWER := 'AACCABAABD';

   FOR R_STUD IN (SELECT STUD_NO, ANS
                  FROM STUD_ANS_SHEET)
   LOOP
      V_CORR := 0;--It's better to have only one update
      V_WRONG := 0;
      V_UNATTEMPT := 0;

      FOR I IN 1 .. 10
      LOOP
         STR2 := SUBSTR (R_STUD.ANS, I, 1);
         STR1 := SUBSTR (ANSWER, I, 1);

         IF (STR2 = STR1)
         THEN
            V_CORR := V_CORR + 1;
         ELSIF (STR2 = 'E')
         THEN
            V_UNATTEMPT := V_UNATTEMPT + 1;
         ELSE
            V_WRONG := V_WRONG + 1;
         END IF;
      END LOOP;

      UPDATE STUD_ANS_SHEET
      SET SCORE = V_CORR- V_WRONG* 0.25 + V_UNATTEMPT,
          CORR_ANS = V_CORR,
          WRONG_ANS = V_WRONG,
          UNATTEMPT_ANS = V_UNATTEMPT
      WHERE R_STUD.STUD_NO = STUD_NO;
   END LOOP;

END;
/

【讨论】：

非常感谢...我今天也是这样，它运行成功

【解决方案3】：

SET SERVEROUTPUT ON;

    DECLARE
       aswer varchar (10);
       v_corr number(3);
       v_wrong number (3);
       v_unattempt number (3);
       str1  VARCHAR (10);
       str2 VARCHAR (10);
    BEGIN
       answer:= 'AACCABAABD';

       FOR v_stud in c_stud
       LOOP
          v_corr:= 0;
          v_wrong:= 0;
          v_unattempt := 0;

          FOR I IN 1 .. 10
          LOOP
             str2 := SUBSTR (v_stud.ans, i, 1);
             str1 := SUBSTR (answer, i, 1);

             IF (str2 = str1)
             THEN
                v_corr := v_corr + 1;
             ELSIF (str2 = 'E')
             THEN
                v_unattempt := v_unattempt + 1;
             else
                v_wrong:= v_wrong + 1;
             END IF;
          END LOOP;

          UPDATE stud_ans_sheet
          SET 
              corr_ans= v_corr,
              wrong_ans = v_wrong,
             unattempt_ans=v_unattempt , score = v_corr- v_wrong* 0.25,
          WHERE stud_no= v_stud.stud_no;
       END LOOP;

    END;
    /

【讨论】：