删除括号之间的字符

Question

我正在使用 SQL Server 2008 R2，但我正在通过 SQL Server 2012 Management Studio 访问该服务器。

我有一个名为Search 的表，其中有一列Body 类型为(nvarchar(Max), not null)。

此列中的数据实际上是电子邮件的正文，此列将所有 HTML 标记作为文本的一部分。

例如，电子邮件正文将显示：

 Good morning
 This invoice has been assigned.

但是当它存储在名为Body 的列中时，它看起来像这样：

[size=14.0pt]Good morning
[/size][size=14.0pt]This invoice has been assigned.[/size] 

我有以下 SQL 来删除“[”和“]”之间的所有内容（包括括号）：

 SELECT 
     *,
     CASE 
        WHEN CHARINDEX('[', Body) > 0 AND CHARINDEX(']', Body) > 0 
             AND CHARINDEX('[', Body) < CHARINDEX(']', Body) 
           THEN STUFF(Body, CHARINDEX('[', Body), (CHARINDEX(']', Body) - CHARINDEX('[', Body)) + 1, '')
           ELSE Body
     END AS Body1
FROM search

但这只是删除了第一组标签，现在看起来像这样：

Good morning
[/size][size=14.0pt]This invoice has been assigned.[/size]

您能帮我处理一下我的 SQL，以便将它们全部删除，看起来像这样：

Good Morning
This invoice has been assigned.

Answer 1

您可以定义一个标量函数来删除方括号以及它们之间包含的所有文本：

create function [dbo].[fx_removetags] (@text nvarchar(max))
    returns nvarchar(max) as
begin
    declare @tag_start  int
    declare @tag_end    int
    declare @tag_length int
    set @tag_start = charindex('[', @text)
    set @tag_end = charindex(']', @text, charindex('[', @text))
    set @tag_length = (@tag_end - @tag_start) + 1
    while @tag_start > 0 and @tag_end > 0 and @tag_length > 0
        begin
            set @text = stuff(@text,@tag_start,@tag_length, '')
            set @tag_start = charindex('[',@text)
            set @tag_end = charindex(']',@text,charindex('[', @text))
            set @tag_length = (@tag_end - @tag_start) + 1
        end
    return ltrim(rtrim(@text))
end

现在您可以调用该函数来获取不带括号的文本：

declare @test nvarchar(max)= ''
set @test = '[size=14.0pt]Good morning [/size][size=14.0pt]This invoice has been assigned.[/size] '

select [dbo].[fx_RemoveTags](@test)

结果：

在您的具体情况下，您可以使用如下函数：

SELECT 
     *,
     [dbo].[fx_RemoveTags](@test) as Body1
FROM search