从函数返回数组时类型不匹配

Question

我正在尝试创建一个函数，用于在 subs 中创建一个月中实际天数的数组。我无法通过直接使用即时窗口或使用子窗口来运行该功能。该函数的代码如下（Debug.Print 实例已被删除，因为它们甚至从未触发）：

Function GenererDager(ByVal month As Integer, ByVal year As Integer) As Integer

    Dim dateFormat As String, daysArr() As Integer, actualDays As Integer

    actualDays = 1

    ' Find the number of actual days in given month
    For dayCheck = 1 To 31

        dateFormat = month & "/" & dayCheck & "/" & year ' mm/dd/yyyy format

        If IsDate(dateFormat) Then

            actualDays = actualDays + 1

        Else

            Exit For

        End If

    Next dayCheck

    ' Redimension the array with the actual number of days in the month
    ReDim daysArr(actualDays)

    ' Populate the array with the correct number of days
    For daysToArray = 1 To actualDays

        daysArr(daysToArray) = daysToArray

    Next daysToArray

    GenererDager = daysArr

End Function

使用带有GenererDager(2, 2017) 的即时窗口运行该函数会产生以下错误消息：Compile error: Expected: =

使用带有?GenererDager(2, 2017) 的即时窗口运行该函数会产生以下错误消息：Compiler error: Type mismatch 并选择了最后一次使用 daysArr

我用来调用函数的 test-sub 如下所示：

Sub HentDager()

    Dim daysArray() As Integer

    daysArray = GenererDager(2, 2017)

    Debug.Print daysArray(4)

End Sub

在即时窗口中使用HentDager() 调用此子会产生以下错误：Compile error: Expected: =

我已经被这个问题困扰了一段时间，并且我已经多次重写代码以识别问题，但到目前为止我一直无法解决它。我可能会产生比我在此过程中修复的错误更多的错误，因为我意识到我不知道我现在真正在做什么:-)

Answer 1

您必须将您的对象和函数声明为 Variant 才能传递数组。

此外，您的函数需要进行一些更改：

• actualDays = actualDays - 1 因为您返回了第一个不是日期的值！
• ReDim daysArr(1 To actualDays) 避免在数组的第一个索引上出现空值，
  这本来是daysArr(0)

工作功能（已测试）：

Function GenererDager(ByVal month As Integer, ByVal year As Integer) As Variant
    Dim dateFormat As String, daysArr() As Variant, actualDays As Integer, dayCheck As Integer, daysToArray As Integer
    actualDays = 1

    ' Find the number of actual days in given month
    For dayCheck = 1 To 31
        dateFormat = month & "/" & dayCheck & "/" & year ' mm/dd/yyyy format
        If IsDate(dateFormat) Then
            actualDays = actualDays + 1
        Else
            Exit For
        End If
    Next dayCheck
    actualDays = actualDays - 1
    ' Redimension the array with the actual number of days in the month
    ReDim daysArr(1 To actualDays)

    ' Populate the array with the correct number of days
    For daysToArray = 1 To actualDays
        daysArr(daysToArray) = daysToArray
    Next daysToArray

    GenererDager = daysArr
End Function

测试：

Sub HentDager()
    Dim daysArray() As Variant
    daysArray = GenererDager(2, 2017)
    'Display last day of the month in the immediate window
    Debug.Print daysArray(UBound(daysArray))
End Sub

经过一番反复试验，这里是一个使用Integer 的示例：

Sub TestIntSub()

    Dim TestInt() As Integer
    TestInt = FctIntArr

    Debug.Print TestInt(1) & "|" & TestInt(2)

End Sub

Public Function FctIntArr() As Integer()
    Dim IntArr() As Integer
    ReDim IntArr(1 To 2)
    IntArr(1) = 545
    IntArr(2) = 232

    FctIntArr = IntArr
End Function

Answer 2

你需要正确定义函数的返回类型-

Function GenererDager(ByVal month As Integer, ByVal year As Integer) As Integer

改成

Function GenererDager(ByVal month As Integer, ByVal year As Integer) As Variant

Answer 3

似乎是错误的事情很少

1. 你的函数返回值实际上是一个整数而不是整数（）

2. 不是将 daysarray 调暗为数组，而是将其调暗为变体并分配值